PAL16L8A
PAT1027
1005 STROBE AND SELECT DECODE                        1984-05-30/\L
                                   (FUNCTION TABLE:  1985-02-28/\L)
IOST' RD'   MUX'  A4    RFSH' A3    WR'   A5    BOOT' GND
A15   CAS'  XMW'  XMFL' BRFS' IO'   SIO'  CTC'  BOE'  VCC


IF(VCC)  /BOE' = /MUX'*/RD'*/BOOT'*/A15

IF(VCC)  /CTC' = A5*A4*/A3*RFSH'

IF(VCC)  /SIO' = A5*A4*A3*RFSH'

IF(VCC)   /IO' = /IOST'*/A5*/A4*/A3

IF(VCC) /BRFS' = /RFSH'

IF(VCC) /XMFL' = /IOST'*/RD'*A5*/A4

IF(VCC)  /XMW' = /IOST'*/WR'*A5*/A4

IF(VCC)  /CAS' = /MUX'*/WR'
               + /MUX'*/RD'*BOOT'
               + /MUX'*/RD'*A15


FUNCTION TABLE:

BOOT' RFSH' A15 A5 A4 A3 MUX' RD' WR' IOST'
BOE' CAS' BRFS' CTC' SIO' XMFL' XMW' IO'

;B R        I     B    X
;O FA    M  O  BC R CS MX
;O S1AAA URWS  OA F TI FMI
;T H5543 XDRT  ES S CO LWO
;' '     ''''  '' ' '' '''
--------------------------
; MEMORY
 L HLLLL HLHH  HH H HH HHH
 L HLLLL LLHH  LH H HH HHH
 L HHLLL HLHH  HH H HH HHH
 L HHLLL LLHH  HL H HH HHH
 H HLLLL HLHH  HH H HH HHH
 H HLLLL LLHH  HL H HH HHH
 L HLLLL HHLH  HH H HH HHH
 L HLLLL LHLH  HL H HH HHH
; REFRESH
 H LLLLL HHHH  HH L HH HHH
; IO SELECT
 H HLHHL HLHL  HH H LH HHH
 H HLHHH HLHL  HH H HL HHH
 H HLHHL HHLL  HH H LH HHH
 H HLHHH HHLL  HH H HL HHH
; STROBES
 H HLHLL HLHL  HH H HH LHH
 H HLHLL HHHL  HH H HH HHH
 H HLHLL HLHH  HH H HH HHH
 H HLHLL HHLL  HH H HH HLH
 H HLHLL HHLH  HH H HH HHH
 H HLLLL HHHL  HH H HH HHL
 H HLLLL HHLL  HH H HH HHL
 H HLLLL HLHL  HH H HH HHL
 H HLHLH HLHL  HH H HH LHH
 H HLHLH HHLL  HH H HH HLH
; NO OPERATION
 H HLLLH HLHL  HH H HH HHH
 H HLLLH HHLL  HH H HH HHH
--------------------------


DESCRIPTION: