;
; LIST.MAC
;
; Sends a file to the list (LST:) device.
;
Vers	equ	10
SubVers	equ	' '
;
; USAGE:
;
;	LIST {dir:}<fn.ft> {/<option>}
;
; An input filename is required.  If a drive, user, or directory name
; is not given, the current drive and/or user is assumed.
;
; The only available option is "G" (graphics mode), which will cause
; LIST to ignore the CP/M end-of-file character (^Z).
;
; Version 1.0 (January 5, 1990) -- Initial release.
;
;	Gene Pizzetta
;	481 Revere Street
;	Revere, MA  02151
;
;	Newton Centre Z-Node (617) 965-7259
;	GEnie (E.Pizzetta)
;	Voice (617) 284-0891
;
;
Bdos	equ	0005h		; BDOS entry
MemTop	equ	Bdos+1		; --> top of memory
CpmFcb	equ	05Ch		; default file control block
FcbName	equ	CpmFcb+1	; filename
FcbEx	equ	CpmFcb+12	; current file extent
FcbUsr	equ	CpmFcb+13	; du user code (set by ZCPR3)
FcbCr	equ	CpmFcb+32	; current record
CpmBuf	equ	080h		; default DMA buffer
TPA	equ	100h		; program load address
;
; BDOS Service Functions
;
FOpen	equ	15
FClose	equ	16
FRead	equ	20
CurDsk	equ	25
SetDMA	equ	26
SetUsr	equ	32
;
; character codes
;
LF	equ	0Ah		; linefeed
FF	equ	0Ch		; formfeed
CR	equ	0Dh		; carriage return
CpmEof	equ	1Ah		; CP/M end of file (^Z)
ESC	equ	1Bh		; escape
;
	ext	pafdc,epstr,cout,condin
	ext	pfn2,codend,z3vinit,stndout,stndend
	ext	lout
;
	MACLIB	Z80
;
	jmp	START
;
	db	'Z3ENV'
	db	1
Z3EAdr:	dw	0FE00h		; address of environment descriptor
;
; screen messages
;
MsgSO:	db	'LIST           Version '
	db	Vers/10+'0','.',Vers mod 10+'0',SubVers,CR,LF,0
MsgUsg:	db	'Usage:',CR,LF
	db	'   LIST {dir:}<fn.ft> {/<option>}',CR,LF
	db	'An input filename is required.',CR,LF
	db	'Option:',CR,LF
	db	'   G  Graphics (ignore ^Z)',0
MsgNFd:	db	'Input file not found.',CR,LF,0
MsgIOE:	db	'Disk I/O error.',CR,LF,0
MsgPrt:	db	'   Printing:  ',0
MsgStp:	db	CR,LF,'Any key stops printing ...',CR,LF,0
MsgUOp:	db	'Unknown option given.',CR,LF,0
MsgUAb:	db	'Printing Stopped at User''s Request.',CR,LF,0
MsgDne:	db	'DONE',CR,LF,0
;
; Start of program . . .
;
START:	sspd	OldStk		; save old stack pointer
	lhld	MemTop		; get top of TPA
	mov	a,h		; move high byte to A
	sui	16		; preserve 4K for CCP and safety
	mov	h,a		; put it back
	sphl			; ..and set new stack pointer
;
	lhld	Z3EAdr		; set up environment
	call	z3vinit
;
	lxi	h,MsgSO		; sign on
	call	epstr
;
	lda	FcbName		; check for input file
	cpi	'"'
	jc	NoTail		; (no file given)
	cpi	'/'		; check for help request
	jnz	IsTail
	lda	FcbName+1
	cpi	'/'
	jz	NoTail		; (we have one)
;
IsTail:	lda	FcbUsr		; get user for file
	sta	FUsr		; ..and store it
;
	lda	CpmFcb		; get drive
	ora	a		; is it the default?
	jrnz	GotDrv		; (no)
	mvi	c,CurDsk	; get default
	call	Bdos
	inr	a		; A=0 changed to A=1
GotDrv:	adi	40h		; make it printable
	sta	FDrv		; ..and store it
	lxi	h,CpmBuf+1	; --> default DMA buffer
	call	SLASH		; look for option
	cpi	0		; was option given?
	jz	NoOpt		; (no option)
	cpi	'G'		; graphics mode?
	jrz	GotOpt		; (yes)
	lxi	h,MsgUOp	; report unknown option
	call	epstr
	jmp	EXIT		; and abort
;
GotOpt:	mvi	a,1		; set option flag
	sta	OptFlg
	jr	CONT
;
NoOpt:	mvi	a,0		; reset option flag
	sta	OptFlg
;
; Everything's set up, so now we open the file, read part of it,
; and start printing ...
;
CONT:	lda	FUsr		; set user area for file
	mov	e,a
	mvi	c,SetUsr
	call	Bdos
	mvi	a,0
	sta	FcbEx		; set extent to 0
	sta	FcbCr		; ..and current record likewise
	mvi	c,FOpen
	lxi	d,CpmFcb	; open input file
	call	Bdos
	inr	a		; does it exist?
	jz	NoFile		; (no, abort)
	call	codend		; get end of code
	shld	DMABuf		; store it
	xchg			; put it in DE
	mvi	c,SetDMA	; ..and set the address
	call	Bdos
;
	call	stndout
	lxi	h,MsgPrt	; report we're printing
	call	epstr
	lda	FDrv		; print drive
	call	cout
	lda	FUsr		; print user
	call	pafdc
	mvi	a,':'		; print colon
	call	cout
	lxi	d,FcbName	; print filename
	call	pfn2
	call	stndend
	lxi	h,MsgStp	; and tell 'em how to stop this thing
	call	epstr
;
; Now we actually start printing ...
;
	call	RdFile		; do initial read
	jz	Finish		; (end-of-file)
PrtMor:	mov	a,m		; get a character
	cpi	CpmEOF		; end of file?
	cz	ChkEOF		; (yes, see if we're done)
	call	lout		; print it
	call	condin		; check console for key
	jnz	UAbort		; (user aborted)
	dcx	b		; decrement counter
	inx	h		; increment pointer
	mov	a,c		; check counter
	ora	b
	jrnz	PrtMor		; (more to go, continue printing
	call	RdFile		; buffer finished, read some more file
	jrnz	PrtMor		; ..and return to printing
;
; This is a normal exit ...
;
Finish:	call	Close		; close file
	lxi	h,MsgDne	; report success
	call	epstr
;
Exit:	lspd	OldStk		; restore old stack
	ret			; ..and return to CCP
;
; We're aborting here, under various circumstances ...
;
NoTail:	lxi	h,MsgUsg	; ..print usage message
	call	epstr
	jr	Abort		; ..and abort
;
NoFile:	lxi	h,MsgNFd	; report file not found
	call	epstr
	jr	Abort		; ..and abort
;
UAbort:	pop	psw		; clear stack
	lxi	h,MsgUAb	; report user aborted
	call	epstr
	call	condin		; get console buffer
;
Abort:	call	Close		; close file
	jmp	Exit
;
; Subroutines ...
;
; RdFile -- reads a sector of the disk file into memory and resets
; the counter and buffer pointer
;
RdFile:	mvi	c,FRead
	lxi	d,CpmFcb	; read in a segment of file
	call	Bdos
	lxi	b,128		; buffer size
	lhld	DMABuf		; set pointer to beginning of DMA Buffer
	cpi	1		; end of file?
	ret
;
; ChkEof
;
ChkEof:	lda	OptFlg		; check mode
	ora	a		; graphics mode?
	rnz			; (yes)
	jmp	Finish		; no, let's go home
;
; Close -- Closes file
;
Close:	lxi	d,CpmFcb
	mvi	c,FClose
	call	Bdos
	ret
;
; SLASH -- returns with the command tail option in A
;
SLASH:	mvi	b,' '		; look for space in command tail
	mvi	c,0		; ..or a null
	call	SCAN
	cmp	b		; was it a space?
	rnz			; (no, return)
	inx	h		; increment pointer
	mov	a,m		; get next byte
	cpi	'/'		; is it a slash?
	jrnz	SLASH		; (no, try again)
	inx	h		; yes, increment pointer again
	mov	a,m		; ..and get option
	ret
;
; SCAN -- called by SLASH to look for a '/' delimiter in the
; command tail
;
SCAN:	mov	a,m		; get byte
	cmp	b		; is it a /?
	rz			; (yes, return)
	cmp	c		; a null then?
	rz			; (yes, return)
	inx	h		; increment pointer
	jr	SCAN		; ..and keep looking
;
	DSEG
;
; uninitialized data
;
OptFlg:	ds	1
OldStk	ds	2
FDrv:	ds	1
FUsr:	ds	1
DMABuf:	ds	2
;
	end