; * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
; *								  *
; *			     D S T A T S			  *
; *								  *
; *	      ZCPR3 Disk/User Statistics Display Utility	  *
; *								  *
; *				 by				  *
; *			     Terry Hazen			  *
; *			21460 Bear Creek Road			  *
; *			 Los Gatos, CA 95030			  *
; *								  *
; *		   Voice.......... (408) 354-7188		  *
; *		   Zee-Machine.... (408) 245-1420		  *
; *		   Ladera Znode... (213) 670-9465		  *
; *								  *
; * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
;
;
; Revision History
; ----------------
;
; 03/30/91	Initial release.
;   v1.0		- Terry Hazen
;
;=======================================================================
;
; DSTATS displays disk space and user statistics and the disk allocation
; bitmap.  It is for CP/M 2.2 ZCPR3 systems only and won't work with
; Z3PLUS.
;
; DSTATS was written to combine both disk and user statistics displays
; in one 2k utility.  I rename it to DISKMAP and use it to check for
; active user areas on hard disk partitions and to check on current
; disk directory statistics and allocation patterns.
;
; The disk statistics routines in DSTATS are derived from DSKMAP10.  The
; user statistics routines are derived from Gene Pizzetta's UMAP10, and
; include the ZRDOS drive byte correction that Gene added in UMAP13.
;
;=======================================================================
;
; Revision
;
vers	equ	10
month	equ	03
day	equ	30
year	equ	91
;
; Equates
;
bell	equ	07
cr	equ	13
lf	equ	10
bdos	equ	05h
fcb1	equ	05ch
fcb2	equ	06ch
cmdbuf	equ	80h
off	equ	0
on	equ	0ffh
;
	.request	vlib,z3lib,syslib
	ext	z3init,z3log
	ext	cin,cout,eprint,epstr,phldc,padc,crlf
	ext	dparams,blkshf,blkmsk,extent,blkmax,dirmax
;
entry:	jp	start		; Executes under ZCPR33+
	db	'Z3ENV'		; ZCPR3 indentifier
	db	1		; Type 1 utility
envptr:	dw	0		; Z3ENV address
;
; Configuration area:
;
; Set to zero to take default lines and columns from the ZCPR3
; environment:
;
lins:	db	0		; Default screen lines for paging
cols:	db	50		; Default screen columns
;
; Default CFG filename and EFCB name buffer
;
name:	db	'DSTATS'	; 8 characters
	db	vers/10+'0',vers mod 10+'0'
	db	0		; Termination
;
pause:	db	on		; ON to pause before allocation map
amap:	db	on		; ON to display allocation map
lblflg:	db	'-'		; Label file flag character

;-----------------------------------------------------------------------
;
; Program start
;
start:	xor	a		; Initialize data area
	ld	hl,data
	ld	de,data+1
	ld	bc,datalen
	ld	(hl),a
	ldir
;
zinit:	ld	hl,(envptr)
	call	z3init
;
	push	hl
	pop	ix		; Get environment address in IX
	ld	a,(ix+3)	; First character of ID string
	cp	'Z'
	jr	z,doschk	; Z-system
;
notz:	call	eprint
	db	cr,lf,'Requires ZCPR3',bell,0
	ret
;
doschk:	ld	l,(ix+24h)	; Get EFCB address in HL
	ld	h,(ix+25h)
	ld	a,h
	or	l		; Check for existence
	jr	z,banner	; No EFCB
;
	inc	hl		; Point to filename
	ld	de,name		; Move it to name buffer
	ld	bc,8
	ldir
;
banner:	call	eprint
	db	'DSTATS vers '
	db	vers/10+'0','.',vers mod 10+'0'
	db	cr,lf,0
;
; Check for Z3PLUS
;
	ld	c,12
	call	bdos		; Get system id
	ld	a,l
	sub	30h
	jr	c,parse		
;
	ld	a,on		; Set Z3PLUS flag
	ld	(z3plus),a
	xor	a
	jr	setm		; Skip option parsing
;
; Parse for option requests
;
parse:	ld	a,'P'		; Pause option?
	call	parscl
	ld	a,(pause)	; Get default pause flag
	jr	nz,setp		; Option not found
	cpl			; Yes, toggle flag
;
setp:	ld	(pausf),a	; Save pause flag
	ld	a,'M'		; Map option?
	call	parscl
	ld	a,(amap)	; Get default map flag
	jp	nz,setm		; Option not found
	cpl			; Yes, toggle flag
;
setm:	ld	(mapf),a	; Save map flag
;
	ld	hl,fcb1+2
	ld	a,'/'		; Help request?
	cp	(hl)
	jp	nz,start1	; No
;
help:	call	eprint
	db	'   Displays disk and user statistics',0
	ld	a,(z3plus)
	or	a
	jr	nz,synt		; No bitmap under Z3PLUS
;
	call	eprint
	db	' plus allocation bitmap',0
;
synt:	call	eprint
	db	cr,lf
	db	'Syntax:',cr,lf,'   ',0
	ld	hl,name		; Point to current filename
	ld	b,8
;
fnlp:	ld	a,(hl)		; Display filename
	inc	hl
	cp	' '
	jr	z,options	; Quit at first space
	call	cout
	djnz	fnlp		; Quit after b characters
;
options:call	eprint
	db	' [dir:]',0
	ld	a,(z3plus)
	or	a
	jp	nz,crlf		; No options under Z3PLUS, so quit now
;
	call	eprint
	db	' [[/]options]',cr,lf
	db	'Options:',cr,lf,'   '
	db	'M - ',0
	ld	a,(mapf)
	call	dont
	call	eprint
	db	'Display allocation map',cr,lf,'   '
	db	'P - ',0
	ld	a,(pausf)
	call	dont
	call	eprint
	db	'Pause before allocation map display',cr,lf,0
	ret
;
dont:	or	a
	ret	z
	call	eprint
	db	'Don''t ',0
	ret
;
start1:	ld	(stack),sp	; Save system stack pointer
	ld	sp,stack	; Point to local stack
	ld	hl,exit		; Save exit address on stack
	push	hl
;
	ld	a,(cols)	; Check if column value specified
	or	a
	jr	nz,getlin	; Use default value
;
	ld	a,(ix+49)	; Get columns from env
;
getlin:	ld	(col),a		; Save number of columns
	inc	hl
	ld	a,(lins)	; Check if line value specified
	or	a
	jr	nz,elin		; Use default value
;
	ld	a,(ix+51)	; Get text lines from env
;
elin:	ld	(lin),a		; Save number of lines
	sub	12
	ld	(lincnt),a	; Lines for first directory screen
;
	ld	a,(fcb1)	; Check if drive specified
	or	a
	jr	nz,getcd	; Yes
;
	ld	c,25
	call	bdos		; Get current drive
	inc	a		; Yes, make it A=1
	ld	(fcb1),a	; Save it
;
getcd:	ld	de,fcb1
	call	z3log
	ld	a,(fcb1+15)	; Valid directory?
	or	a
	jr	z,parm		; Yes
;
	call	eprint
	db	'   Invalid directory',cr,lf,bell,0
	ret
;
parm:	call	dparams
	ld	a,(blkshf)
	cp	7		; 3<BSH<7, else non-standard DPB
	jr	nc,baddpb
;
	cp	3
	jr	nc,blks
;
baddpb:	call	eprint
	db	'   Non-std disk parameter block!',cr,lf,bell,0
	ret
;
blks:	call	eprint
	db	lf,'Drive ',0
	ld	a,(fcb1)
	add	'@'
	call	cout
	call	eprint
	db	':',cr,lf,0
;
	call	eprint
	db	'  Block size........  ',0
;
	ld	a,(blkshf)	; Get BLS
	ld	b,a
	ld	hl,20h		; Initialize register
;
blksz:	add	hl,hl		; Get block size
	djnz	blksz
;
	ld	a,h
	call	padc
	call	eprint
	db	'k',cr,lf
	db	'  Disk capacity.....',0
;
	ld	hl,(blkmax)	; Get DSM+1
	call	size		; HL=size in k
	ld	(dskcap),hl	; Save disk capacity
	call	kout		; Display it
;
	ld	a,(z3plus)
	or	a
	jr	z,getav		; Do it per CP/M2.2
;
; Get disk free space the Z3PLUS way...
;
	ld	a,(fcb1)	; Get disk byte (A=1)
	dec	a		; Make it A=0
	ld	e,a
	ld	c,46		; Free space
	call	bdos
;
; Calculate number of blocks from number of records
;    HL=pointer to 24 bit size in 128 byte records
;
	ld	e,(hl)		; Get low byte in E
	inc	hl
	ld	d,(hl)		; Get middle byte in D
	inc	hl
	ld	c,(hl)		; Get high byte in C
;
; C, DE = 24 bit size, in 128 byte records (high byte in C)
;
	ld	hl,(blkmsk)	; Get block mask
	ld	h,0		; Only one byte
	add	hl,de		; Round to next block
;
; Number of blocks:  Shift HL right blkshf times
;
	ld	a,(blkshf)	; Block shift factor
	ld	b,a
;
shift:	srl	c		; Shift hi byte right, 0 fill
	rr	h		; Roll mid byte with carry from hi byte
	rr	l		; Roll lo byte with carry from mid byte
	djnz	shift		; Repeat until count is zero
	jr	fre04		; And go convert to number of k
;
; Get disk free space the CP/M 2.2 way...
;
getav:	ld	c,27
	call	bdos		; Get ALLOC address
	ld	(alloc),hl	; Save it
	ld	b,h		; BC=ALLOC address
	ld	c,l
	ld	hl,(blkmax)	; Get DSM+1
	ld	de,0		; Initialize free block count
;
; At this point, we have:
;	BC=ALLOC address
;	DE=Free block count
;	HL=Max data block number
;
free:	push	bc		; Save alloc map pointer
	ld	a,(bc)		; Get allocation byte
	ld	b,8		; Process 8 blocks
;
fre01:	rla			; Rotate block bit into CARRY
	jr	c,fre02		; Bit=1, block allocated
	inc	de		; Bit=0, block not allocated
;
fre02:	ld	c,a		; Save remaining allocation bits in C
	dec	hl		; Count down number of disk blocks
	ld	a,l
	or	h
	jr	z,fre03		; No more space left
;
	ld	a,c		; Restore remaining allocation bits
	djnz	fre01		; Loop through 8 bits
;
	pop	bc		; Restore alloc map pointer
	inc	bc		; Point to next byte
	jr	free		; Process it
;
fre03:	pop	bc		; Clear stack
	ex	de,hl		; HL=free block count
;
fre04:	call	size		; HL=size in k
	push	hl		; Save free space
;
	or	a		; Clear CARRY
	ex	de,hl
	ld	hl,(dskcap)	; Total space
	sbc	hl,de		; Get space allocated
;
	call	eprint
	db	'  Space used........',0
	call	kout		; Display it
;
	call	eprint
	db	'  Remaining space...',0
	pop	hl		; Free space
	call	kout		; Display it
	call	crlf
;
; Display directory stats
;
diru:	call	eprint
	db	'Directory usage:',cr,lf
	db	'  User/Label      Files  Entries',cr,lf,0
	call	line
	ld	a,'?'		; Replace drive byte in case ZRDOS
	ld	(ourfcb),a	; Zero'd it out (from UMAP13)
;
	ld	de,ourfcb
	ld	c,17		; Search first
	call	bdos
	cp	0ffh
	jr	z,prtit		; Do final display
;
	call	addit		; Add to table
;
dirlp:	ld	de,ourfcb	; Wildcard fcb
	ld	c,18		; Search next
	call	bdos
	cp	0ffh
	jr	z,prtit		; Do final display
;
	call	addit		; Add to table
	jr	dirlp
;
; Print file counts
;
prtit:	ld	b,0		; Start with user 0
	ld	iy,cnttbl	; Point to table (user 0)
;
prtlp:	ld	a,(iy)		; Any entries?
	or	(iy+1)
	jp	z,prtlp1	; (nope, don't print it)
;
	call	twosp
	ld	a,(fcb1)
	add	'@'
	call	cout
;
	ld	a,b		; Display user number
	push	bc
	ld	b,'0'-1
	cp	10
	jr	nc,prusr1
;
	push	af
	ld	a,'0'
	call	cout
	pop	af
	jr	prusrd
;
prusr1:	inc	b
	sub	10
	jr	nc,prusr1
;
	add	a,10
	ld	c,a
	ld	a,b
	call	cout
	ld	a,c
;
prusrd:	add	a,'0'
	call	cout
	pop	bc
;
	ld	a,':'
	call	cout
;
	push	bc
	ld	a,(iy+4)	; Check for label file
	or	a
	jr	nz,dfn		; Display filename
;
	ld	b,8		; No file, pad with spaces
	call	spcs
	jr	lfpdun
;
dfn:	push	iy
	pop	hl
	ld	de,4
	add	hl,de
	ld	b,8
;
pfnlp:	ld	a,(hl)		; Display filename
	inc	hl
	call	cout
	djnz	pfnlp		; Quit after b characters
;
lfpdun:	pop	bc
	call	foursp
	ld	l,(iy+2)	; Print number of files
	ld	h,(iy+3)
	call	phldc
;
	call	foursp
	ld	l,(iy)		; Print number of entries
	ld	h,(iy+1)
	call	phldc
;
	call	crlf
	call	pagchk
;
prtlp1:	exx			; Increment table pointer to next user
	ld	de,16
	add	iy,de
	exx
	inc	b		; Increment user
	ld	a,b
	cp	32		; Last user?
	jp	c,prtlp		; (no, loop)
;
totals:	call	line
	call	pagchk
;
	call	eprint
	db	'  Totals:',0
	ld	b,9
	call	spcs
	ld	hl,(filcnt)	; Print total files
	call	phldc
	call	foursp
;
atlast:	ld	hl,(entcnt)	; Print total entries
	call	phldc
	ex	de,hl		; Total entries to DE
	ld	hl,(dirmax)	; Get maximum directory entries
	or	a		; Reset carry
	sbc	hl,de		; Calculate remaining entries
	call	eprint
	db	cr,lf,'  Free entries:',0
	ld	b,12
	call	spcs
	call	phldc		; And print it
;
; Display allocation bitmap
;
	ld	a,(z3plus)	; Quit now if Z3PLUS
	or	a
	ret	nz
;
	ld	a,(mapf)	; Display alloc map?
	or	a
	ret	z		; No
;
	call	crlf
	call	crlf
;
	ld	a,(pausf)	; Pause?
	or	a
	jr	z,domap		; No
;
	call	eprint
	db	'[Allocation map or ^C to quit] ',0
	call	cin
	call	eprint
	db	cr,0
	cp	3
	ret	z		; Quit if ^C
;
domap:	ld	bc,(alloc)	; BC=ALLOC address
	ld	hl,(blkmax)	; Get DSM+1
	call	initlin		; Initialize line and column counts
;
; At this point, we have:
;	BC=ALLOC address
;	DE=Line and column
;	HL=Max data block number
;
map:	push	bc		; Save alloc map pointer
	ld	a,(bc)		; Get allocation byte
	ld	b,8		; Process 8 blocks
;
map01:	rla			; Rotate block bit into CARRY
	ld	c,a		; Save remaining allocation bits in C
	jr	c,map02
;
	call	out0		; Bit=0, display non-allocated block
	jr	map03
;
map02:	call	out1		; Bit=1, display allocated block
;
map03:	dec	hl		; Count down number of disk blocks
	ld	a,l
	or	h
	jr	z,exit		; Done
;
	call	chklc		; Check line and column numbers
	ld	a,c		; Restore remaining allocation bits
	djnz	map01		; Loop through 8 bits
;
	pop	bc		; Restore alloc map pointer
	inc	bc		; Point to next byte
	jr	map		; Process it
;
; Main exit
;
exit:	call	crlf
	ld	sp,(stack)
	ret

;-----------------------------------------------------------------------
;
; Subroutines
;
; Add file to counts
;
addit:	add	a		; Point to file entry
	add	a
	add	a
	add	a
	add	a
	ld	e,a
	ld	d,0
	ld	ix,cmdbuf
	add	ix,de
	ld	a,(ix)
	cp	0e5h		; Deleted file?
	ret	z		; (yes, skip it)
;
	ld	de,16		; 16-byte table entries
	ld	iy,cnttbl	; Point to table
	cp	0		; User 0?
	jr	z,addusr	; (yes, no offset needed)
;
	cp	32		; User above 31?
	jr	nc,addend	; (yes, skip it)
;
	ld	b,a		; Move user to B as counter
;
addlp:	add	iy,de		; Calculate offset
	djnz	addlp
;
addusr:	ld	l,(iy)		; Get entry count into HL
	ld	h,(iy+1)
	inc	hl		; Increment it
	ld	(iy),l		; And store it back
	ld	(iy+1),h
	ld	a,(extent)	; Get extent mask
	inc	a		; Increment it
	ld	c,a		; And store it in C
	ld	a,(ix+14)	; Get data module number
	or	a
	jr	nz,addend	; (not zero, so skip)
;
	ld	a,(ix+12)	; Get extent
	cp	c		; Compare to incremented mask
	jr	nc,addend	; (not first extent)
;
	ld	l,(iy+2)	; Get file count into HL
	ld	h,(iy+3)
	inc	hl		; Increment it
	ld	(iy+2),l	; And store it back
	ld	(iy+3),h
;
addend:	ld	hl,(entcnt)	; Increment entry total
	inc	hl
	ld	(entcnt),hl
	ld	a,(ix+14)	; Check data module
	or	a
	ret	nz		; (not zero, so skip)
;
	ld	a,(ix+12)	; Get extent
	cp	c		; Compare to extent mask (+1) in C
	ret	nc		; (not first extent)
;
	push	ix
	pop	hl
	inc	hl		; Point to filename
	ld	a,(lblflg)	; Get label file flag
	cp	(hl)
	jr	nz,nolab	; Not label
;
	push	iy
	pop	de		; Point to destination in table
	inc	de
	inc	de
	inc	de
	inc	de
	ld	bc,11
	ldir
;
nolab:	ld	hl,(filcnt)	; Increment file total
	inc	hl
	ld	(filcnt),hl
	ret
;
; Convert number of blocks in HL to size in k in HL
;
size:	ld	a,(blkshf)	; Get BSH
	sub	3		; Convert to block size
	ld	b,a
	or	a		; Done if 1k blocks
	jr	z,kout
;
incbsz:	add	hl,hl
	djnz	incbsz
	ret
;
; Display size in k
;
kout:	call	phldc
	call	eprint
	db	'k',cr,lf,0
	ret
;
; Display allocated and unallocated blocks as '0' and '1'
;
out1:	ld	a,'1'
	jr	out00
;
out0:	ld	a,'0'
;
out00:	jp	cout
;
; Check line and column numbers and format screen accordingly
;
chklc:	dec	d		; Decrement column count
	ret	nz
;
	call	initcol		; Initialize COL value
	call	crlf		; And start new line
;
	dec	e		; Decrement line count
	ret	nz
;
	call	more		; Pause
	jp	z,exit		; Quit if ^C
;
	call	crlf		; Leave [More] as marker
;
initlin:ld	a,(lin)		; Get number of screen lines
;
savlin:	ld	e,a		; Save remaining lines and fall thru
;
initcol:ld	a,(col)		; Get number of screen columns
	sub	2		; Don't display in last column
	ld	d,a
	ret
;
; Page end - quit with ^C
;
more:	call	eprint
	db	'[More] ',0
	call	cin		; Wait for key
	cp	3		; ^C
	ret
;
; Increment line counter and check for screen fill
;
pagchk:	ld	hl,lincnt	; Decrement line counter
	dec	(hl)
	ret	nz		; (not end of screen)
;
	call	more		; Pause
	jp	z,exit		; Quit if ^C
;
	call	eprint		; Else wipe out message
	db	cr,'       ',cr,0
;
	ld	a,(lin)		; Reset line counter
	ld	(lincnt),a
	ret
;
; Display spaces, saving bc
;
foursp:	push	bc
	ld	b,4
	jr	sps
;
twosp:	push	bc
	ld	b,2
sps:	call	spcs
	pop	bc
	ret
;
spcs:	ld	a,' '
	call	bout
	ret
;
; Display dashed line
;
line:	call	twosp
	ld	b,30
	ld	a,'-'
	call	bout
	jp	crlf		; Finish off with new line
;
bout:	call	cout
	djnz	bout
	ret
;
; Force ZSYSCHK to use epstr
;
pstr:	jp	epstr
;
; Parse fcb for options
;
parscl:	ld	hl,fcb1+1
	ld	bc,20
	cpir
	ret
;
; Initialized data
;
; Wildcarded file control block for Search First and Search Next
;
ourfcb:	db	'?','???????????','?',0,'?'
;
; Uninitialized data area
;
	dseg
	ds	48		; Local stack
stack:	ds	2		; System stack pointer
;
data:
alloc:	ds	2		; Address of allocation vectors
dskcap:	ds	2		; Disk capacity
lin:	ds	1		; Lines for alloc map display
col:	ds	1		; Columns for alloc map display
z3plus:	ds	1		; ON if running under Z3PLUS
mapf:	ds	1		; ON to display alloc map
pausf:	ds	1		; ON to pause before alloc map display
lincnt:	ds	1		; Current line count
filcnt:	ds	2		; Current file total
entcnt:	ds	2		; Current entry total
;
; Table with a 16 byte entry for each user area.
; The first word for each user is the number of directory entries.
; The second word for each user is the number of files.
; The final 12 bytes is the label filename, if any, plus one spare byte
;
cnttbl:	ds	32*16		; 32 users * 16 bytes @
datalen	equ	$-data

	end