; Library:	ZSLIB
; Version:	2.1
; Module:	ZSPRDAT3
; Version:	1.1
; Author:	Carson Wilson
; Date:		February 2, 1990
; Changes:	Shortened code.  No longer tests for invalid date/time.

; Version:	1.0
; Author:	Carson Wilson
; Date:		February 16, 1989
; Changes:	Now uses day to validate stamps (for CP/M Plus).

; Version:	0.1
; Author:	Carson Wilson
; Date:		August 9, 1988
; Purpose:	Print date in short form.
;

	PUBLIC	PRDAT3

	EXTRN	COUT,PA2HC			; SYSLIB

;
; PRDAT3 - Print short form of date, e.g., "03/02/88"
;
;	Entry:	<HL> - points to date as BCD yy mm dd.
;	Exit:	- Date printed.
;	Uses:	- none.
;
PRDAT3:
	push	hl
	push	af

	inc	hl	

; Print month

	call	PM2HC
	call	SLASH

; Print day

	inc	hl		; Day
	call	PM2HC
	call	SLASH

; Print year

	dec	hl
	dec	hl		; Year
	call	PM2HC

	pop	af
	pop	hl
	ret
	

; ------------------------------------
;
; Subroutines
;
SLASH
	ld	a,'/'
	jp	COUT


; PM2HC - Print value at (HL) as 2 hex chars.

PM2HC:
	ld	a,(hl)
	jp	PA2HC		; Display & return

	end

; End ZSPRDAT3.Z80