; Library:	ZSLIB
; Version:	1.0
; Module:	ZSDOSTYP
; Version:	1.0
; Author:	Carson Wilson
; Date:		August 10, 1988
; Purpose:	Test for presence of ZSDOS.
;

	PUBLIC	DOSTYP,CPMVER,DOSVER

BDOSPTR	equ	5
CPMV	equ	12
EXDOSV	equ	48	; Extended BDOS version

;
; DOSTYP - Determine BDOS type.
;
;	Entry:	- none.
;	Exit:	<F>  - Zero flag reset (NZ) if extended BDOS present.
;		<A>  - contains extended BDOS identifier, or 0FFh if none.
;		(CPMVER) contains the CP/M version. 
;	Uses:	- <AF>.
;	Notes:	For convenience, (DOSVER) = A on exit.
;		The only extended BDOS identifiers currently in use are:
;			 0	- ZRDOS
;			'S'	- ZSDOS
;			'D'	- ZDDOS
DOSTYP:
	push	hl
	push	de
	push	bc

	ld	c,CPMV
	call	BDOSPTR
	ld	a,l
	ld	(CPMVER),a
	ld	c,EXDOSV
	call	BDOSPTR
	ld	a,l
	or	a		; Extended BDOS?
	ld	a,0FFh
	jr	z,DOSTX		; No, flag with 0FFh, return (Z)
	ld	a,h		; Yes, save identifier, return (NZ)
DOSTX:	ld	(DOSVER),a

	pop	bc
	pop	de
	pop	hl
	ret

; Data

	DSEG

DOSVER:	ds	1

CPMVER:	ds	1

	end

; End ZSDOSTYP.Z80