; SHOWFILE.Z80

fnames:
	call	banner
	call	gxymsg
	defb	3,30
	defb	highon,' System File Names ',highoff,0

	ld	hl,7*100h+22	; Set to row 7, column 22
	ld	(infoxy),hl

	call	vprxy
	defb	highon
	defb	' Shell Variable File: '
	defb	highoff,'  ',0

	ld	a,47h		; Offset in ENV
	call	compenv
	ex	de,hl		; DE points to file name
	call	pfn		; Print file name

	call	dispxy
	call	dispxy
	ld	c,'1'		; Set file number
	ld	b,4		; Number of names to display
fnames1:
	ld	hl,11		; Offset to next file
	add	hl,de		; Point to next file name
	ex	de,hl
	call	vprxy
	defb	highon
	defb	' System File Name ',0
	ld	a,c
	call	cout		; Print number
	call	vprint
	defb	':  '
	defb	highoff,'  ',0
	call	pfn		; Print file name
	inc	c		; Next file number
	djnz	fnames1

	jp	getcmd

;----------------------------------------

; Subroutine for displaying the name of a file

pfn:
	ld	a,(de)		; Get first character
	cp	' '		; Anything defined?
	jp	nz,pfn1		; If so, display name (SYSLIB routine)
	ld	hl,8		; Check the file type
	add	hl,de
	ld	a,(hl)		; Get first character of type
	cp	' '		; Anything defined?
	jp	nz,pfn1		; If so, display name (SYSLIB routine)
	call	print		; Otherwise give 'undefined' message
	defb	'-undefined-',0
	ret

; End SHOWFILE.Z80