; AUTHORIZ v1.00 01/18/84
; By ESKAY
;
; part of the RTDS system
; sysop use only
;
cr	equ	0dh
lf	equ	0ah
;
tdos	equ	50h
setpar	equ	90h		;set parameter call
getpar	equ	91h		;get parameter call
dbuff	equ	80h		;default buffer
uacl	equ	dbuff		;access level storage
ulog	equ	dbuff+1		;logged flag
uname	equ	dbuff+10h	;caller's name
;
.request syslib
	extrn	bbline,print,pstr,crlf
	extrn	eval10,pafdc
;
.z80
;
start:	ld	sp,stack
	call	print
	cr,lf
	'[RTDS (c) 1985 ESKAY]',cr,lf
	'[AUTHORIZ  ver  1.00]',cr,lf,lf
	'Enter station number (1..15) to change ACL on :',0
	call	bbline
	or	a
	jp	z,quit
	call	eval10		;make hex
	or	a
	jp	z,quit
	cp	16
	jp	nc,quit
	ld	a,d
	or	a
	jp	nz,quit
	ld	(statn),de	;save station number = circ/node
	ld	bc,0feh*256+41	;b=-2, c=t-fcn 41
	ld	h,getpar
	call	tdos
	ld	a,(ulog)
	cp	77h
	jr	z,logged
	call	print
	cr,lf,lf
	'Error - no user logged there!',cr,lf,0
	rst	0
;
logged:	call	print
	cr,lf,lf
	'Name = ',0
	ld	hl,uname
	call	pstr
	call	print
	', current ACL = ',0
	ld	a,(uacl)
	call	pafdc
	call	print
	cr,lf
	'New access level (0..9, anything else = unchanged : ',0
	call	bbline
	or	a
	jp	z,nochg
	ld	a,(hl)
	cp	'0'
	jp	c,nochg
	cp	'9'+1
	jp	nc,nochg
	and	0fh
	ld	(uacl),a
	push	af
	ld	bc,0feh*256+41
	ld	h,setpar
	ld	de,(statn)
	call	tdos
	pop	af
	call	print
	cr,lf,lf
	'Access level CHANGED TO ',0
	call	pafdc
	jr	quit
;
nochg:	call	print
	cr,lf
	'Access level UNCHANGED',0
quit:	call	print
	cr,lf,lf,0
	rst	0
;
statn:	dw	0
	ds	80
stack	equ	$
	end