;

      TITLE ZMOC-1.Z80 - 01/01/88 - ZMD I/O Overlay for OSBORNE 1/COMM PAC
;				    Copyrighted (c) 1987, 1988
;				    Robert W. Kramer III

	PAGE
;-									 -;
;                         Update History                                  ;
;                                                                         ;
;    Date	Release			     Comments                     ;
;  --------	-------	  ----------------------------------------------  ;
;                                                                         ;
;  01/01/88	v1.00	- Initial version				  ;
;-                                                                       -;

;
MODDATP EQU	2A01H		; Data in port
MODDATO EQU	MODDATP		; Data out port
MODCTLP EQU	MODDATP-1	; Control/status port
MODSNDB EQU	2		; Bit to test for send
MODSNDR EQU	2		; Value when ready
MODRCVB EQU	1		; Bit to test for receive
MODRCVR EQU	1		; Value when ready
MODDCDB EQU	4		; Carrier detect bit
MODDCDA EQU	4		; Value when active
MODPARE EQU	40H		; Value for parity error
MODOVRE EQU	10H		; Value for overrun error
MODFRME EQU	20H		; Value for framing error

;
;-------------------------------------------------------------------------;
; Input/Output Jump Table						  |
;-------------------------------------------------------------------------;
;

	ORG	0580H		; Start after configuration table

	JP	0000H		; See CONOUT.INF
	JP	INIT		; Initialization routine
	JP	UNINIT		; Unititialize routine
	JP	SNDCHR		; Send character
	JP	CARCHK		; Test for carrier
	JP	GETCHR		; Get character from modem
	JP	RCVRDY		; Check receive ready
	JP	SNDRDY		; Check send ready

;
;-------------------------------------------------------------------------;
; System startup inititialization routine				  |
;-------------------------------------------------------------------------;
;

INIT:	RET

;
;-------------------------------------------------------------------------;
; System exit unititialization routine					  |
;-------------------------------------------------------------------------;

UNINIT:	RET

;
;-------------------------------------------------------------------------;
; Send character out modem						  |
;-------------------------------------------------------------------------;

SNDCHR:	POP	AF		; Get the character back
	DI			; Disable interrupts
	OUT	(0),A		; Switch to alternate page
	LD	(MODDATO),A	; Send data byte
	OUT	(1),A		; Switch pages back
	EI			; Re-enable interrupts
	RET

;
;-------------------------------------------------------------------------;
; Check for carrier							  |
;-------------------------------------------------------------------------;

CARCHK:	CALL	OSTAT		; Get status
	AND	MODDCDB		; Get carrier detect bit
	PUSH	AF
	CALL	NZ,GETCHR
	POP	AF
	RET

;
;-------------------------------------------------------------------------;
; Get character from modem						  |
;-------------------------------------------------------------------------;

GETCHR:	DI			; Disable interrupts
	OUT	(0),A		; Switch to alternate page
	LD	A,(MODDATP)	; Get data byte
	OUT	(1),A		; Switch pages back
	EI			; Re-enable interrupts
	RET

;
;-------------------------------------------------------------------------;
; Check modem receive ready						  |
;-------------------------------------------------------------------------;

RCVRDY:	CALL	OSTAT		; Get modem status
	PUSH	BC		; Save scratch register
	PUSH	AF		; Check error status
	AND	MODFRME+MODOVRE
	LD	B,A		; Save it for a moment
	POP	AF
	AND	MODRCVB		; Isolate ready bit
	CP	MODRCVR		; Test it
	LD	A,B		; Get the error code char. back
	POP	BC
	RET

;
;-------------------------------------------------------------------------;
; Check modem send ready						  |
;-------------------------------------------------------------------------;

SNDRDY:	CALL	OSTAT		; Get status byte
	AND	MODSNDB		; Isolate ready bit
	CP	MODSNDR		; Ready to send?
	RET

;
; Special routine to get status byte
;
OSTAT:	DI			; Disable interrupts
	OUT	(0),A		; Switch to alternate page
	LD	A,(MODCTLP)	; Get status byte
	OUT	(1),A		; Switch pages back
	EI			; Re-enable interrupts
	RET


	END