;

      TITLE ZMLO-1.Z80 - 01/01/88 - ZMD I/O Overlay for LOBO MAX-80
;				    Copyrighted (c) 1987, 1988
;				    Robert W. Kramer III

	PAGE
;-									 -;
;                         Update History                                  ;
;                                                                         ;
;    Date	Release			     Comments                     ;
;  --------	-------	  ----------------------------------------------  ;
;                                                                         ;
;  01/01/88	v1.00	- Initial version				  ;
;-                                                                       -;

;
MODDATP EQU	0F7E4H		; Data in port
MODCTLP EQU	MODDATP+1	; Control/status port
MODSNDB EQU	04H		; Bit to test for send
MODSNDR EQU	04H		; Value when ready
MODRCVB EQU	01H		; Bit to test for receive
MODRCVR EQU	01H		; Value when ready
MODDCDB EQU	08H		; Carrier detect bit
MODDCDA EQU	08H		; Value when active
MODPARE EQU	10H		; Value for parity error
MODOVRE EQU	20H		; Value for overrun error
MODFRME EQU	40H		; Value for framing error
MODRESI EQU	10H		; Reset external status/interrupts
MODERES EQU	30H		; Error reset

;
;-------------------------------------------------------------------------;
; Input/Output Jump Table						  |
;-------------------------------------------------------------------------;
;

	ORG	0580H		; Start after configuration table

	JP	0000H		; See CONOUT.INF
	JP	INIT		; Initialization routine
	JP	UNINIT		; Unititialize routine
	JP	SNDCHR		; Send character
	JP	CARCHK		; Test for carrier
	JP	GETCHR		; Get character from modem
	JP	RCVRDY		; Check receive ready
	JP	SNDRDY		; Check send ready

;
;-------------------------------------------------------------------------;
; System startup inititialization routine				  |
;-------------------------------------------------------------------------;

INIT:	RET

;
;-------------------------------------------------------------------------;
; System exit unititialization routine					  |
;-------------------------------------------------------------------------;

UNINIT:	RET

;
;-------------------------------------------------------------------------;
; Send character out modem						  |
;-------------------------------------------------------------------------;

SNDCHR:	POP	AF		; Get the character back
	LD	(MODDATP),A	; Send it to the modem output
	RET

;
;-------------------------------------------------------------------------;
; Check for carrier							  |
;-------------------------------------------------------------------------;

CARCHK:	LD	A,MODRESI	; Reset external status/interrupts
	LD	(MODCTLP),A
	LD	A,(MODCTLP)	; Get status
	AND	MODDCDB		; Get carrier detect bit
	CP	MODDCDA		; Test bit
	RET

;
;-------------------------------------------------------------------------;
; Get character from modem						  |
;-------------------------------------------------------------------------;

GETCHR:	LD	A,(MODDATP)	; Get character from data in port
	RET

;
;-------------------------------------------------------------------------;
; Check modem receive ready						  |
;-------------------------------------------------------------------------;

RCVRDY:	LD	A,(MODCTLP)	; Get modem status
	PUSH	BC		; Save scratch register
	PUSH	AF
	LD	A,1+MODRESI	; Select read register 1
	LD	(MODCTLP),A
	LD	A,(MODCTLP)	; Read the error status
	AND	MODFRME+MODOVRE+MODPARE
	LD	B,A		; Save it for a moment
	LD	A,MODERES
	LD	(MODCTLP),A	; Do an error reset command
	POP	AF		; Now get modem status back
	AND	MODRCVB		; Isolate ready bit
	CP	MODRCVR		; Test it
	LD	A,B		; Get the error code char. back
	POP	BC
	RET

;
;-------------------------------------------------------------------------;
; Check modem send ready						  |
;-------------------------------------------------------------------------;

SNDRDY:	LD	A,(MODCTLP)	; Get status byte
	AND	MODSNDB		; Isolate ready bit
	CP	MODSNDR		; Ready to send?
	RET


	END