;

      TITLE ZMIN-1.Z80 - 01/01/88 - ZMD I/O Overlay for INTERFACER 3/4
;				    Copyrighted (c) 1987, 1988
;				    Robert W. Kramer III

	PAGE
;-									 -;
;                         Update History                                  ;
;                                                                         ;
;    Date	Release			     Comments                     ;
;  --------	-------	  ----------------------------------------------  ;
;                                                                         ;
;  01/01/88	v1.00	- Initial version				  ;
;-                                                                       -;

;
MODDATP EQU	10H		; Data in port
MODDATO EQU	MODDATP		; Data out port
MODCTLP EQU	MODDATP+1	; Control/status port
MODCTL2 EQU	MODDATP+1	; Second control/status port
MODUPRT EQU	MODDATP+7	; Chip select port
MODUSER EQU	6		; Modem I/O on inter-3 board		
MODSNDB EQU	1		; Bit to test for send
MODSNDR EQU	1		; Value when ready
MODRCVB EQU	2		; Bit to test for receive
MODRCVR EQU	2		; Value when ready
MODDCDB EQU	80H		; Carrier detect bit (DSR line from 2651)
MODDCDA EQU	80H		; Value when active

;
;-------------------------------------------------------------------------;
; Input/Output Jump Table						  |
;-------------------------------------------------------------------------;
;

	ORG	0580H		; Start after configuration table

	JP	0000H		; See CONOUT.INF
	JP	INIT		; Initialization routine
	JP	UNINIT		; Unititialize routine
	JP	SNDCHR		; Send character
	JP	CARCHK		; Test for carrier
	JP	GETCHR		; Get character from modem
	JP	RCVRDY		; Check receive ready
	JP	SNDRDY		; Check send ready

;
;-------------------------------------------------------------------------;
; System startup inititialization routine				  |
;-------------------------------------------------------------------------;

INIT:	RET

;
;-------------------------------------------------------------------------;
; System exit unititialization routine					  |
;-------------------------------------------------------------------------;

UNINIT:	RET

;
;-------------------------------------------------------------------------;
; Send character out modem						  |
;-------------------------------------------------------------------------;

SNDCHR:	LD	A,MODUSER	; Select proper chip
	OUT	(MODUPRT),A
	POP	AF		; Get the character back
	OUT	(MODDATO),A	; Send it to the modem output
	RET

;
;-------------------------------------------------------------------------;
; Check for carrier							  |
;-------------------------------------------------------------------------;

CARCHK:	LD	A,MODUSER	; Select proper chip
	OUT	(MODUPRT),A
	IN	A,(MODCTLP)	; Get status
	AND	MODDCDB		; Get carrier detect bit
	CP	MODDCDA		; Test bit
	RET

;
;-------------------------------------------------------------------------;
; Get character from modem						  |
;-------------------------------------------------------------------------;

GETCHR:	LD	A,MODUSER	; Select proper chip
	OUT	(MODUPRT),A
	LD	A,MODDATP
	IN	A,(MODDATP)	; Get character from data in port
	RET

;
;-------------------------------------------------------------------------;
; Check modem receive ready						  |
;-------------------------------------------------------------------------;

RCVRDY:	LD	A,MODUSER	; Select proper chip
	OUT	(MODUPRT),A
	IN	A,(MODCTLP)	; Get modem status
	AND	MODRCVB		; Isolate ready bit
	CP	MODRCVR		; Test it
	RET

;
;-------------------------------------------------------------------------;
; Check modem send ready						  |
;-------------------------------------------------------------------------;

SNDRDY:	LD	A,MODUSER	; Select proper chip
	OUT	(MODUPRT),A
	IN	A,(MODCTLP)	; Get status byte
	AND	MODSNDB		; Isolate ready bit
	XOR	MODSNDR		; Ready to send?
	RET


	END