100 ON ERROR GOTO 920
110 ' Check out the CLS sequence first
120 OPEN "I",#1,"PUBCAT.DAT"
130 WHILE NOT EOF(1)
140 LINE INPUT#1,A$
150 IF LEFT$(A$,3)="299" THEN 180
160 IF LEFT$(A$,3)="999" THEN 190
170 CLS$=CLS$+CHR$(VAL(A$))
180 WEND
190 CLOSE
200 ' Init 14 Aug 1987 @ 6:25
210 ' Now define some screen functions
220 LOGO$="PUBTOOL    v1    [PubKMD]"
230 CPRT$="(c)   AB17 Remote Systems"
240 DEAD$="<ESC> will  Abort Program
250 TYPE$="Your System Name"
260 ' Set up the exclusions list
270 D1$="G10":D2$="G10"
280 HS1$="P":HS2$="R"
290 EN0$="OBJ":EN1$="COM":EN2$="FIX":EN3$="TXT":EN4$="TZT":EN5$="NOT"
300 EN6$="   ":EN7$="MZC":EN8$="AZM":EN9$="ASM":EN10$="BAS"
310 SYSP$="AB17 SYSOP"
320 ' Get screen stuff and print "when" question
330 GOSUB 820
340 PRINT"Month to begin with [1-12] ? ";:INPUT"",M$
350 IF VAL(M$)<1 OR VAL(M$)>12 THEN 330
360 ' Now open the KMD.LOG for a valid records count
370 GOSUB 820
380 OPEN "I",#1,"KMD.LOG"
390 IF EOF(1) THEN 470
400 LINE INPUT#1,A$
410 IF INKEY$=CHR$(27) THEN CLOSE:END
420 GOSUB 870
430 IF CHEK<VAL(M$) THEN GOSUB 880
440 IF CHEK>=VAL(M$) THEN OK=OK+1:PRINT TAB(63)"Possible => ";OK;
450 PRINT CHR$(13);:GOTO 390
460 IF CHEK<VAL(M$) THEN 390
470 TR=OK
480 CLOSE
490 ' That taken care of we begin main part of program
500 OPEN "I",#1,"KMD.LOG":OPEN "O",#2,"PUBKMD.DAT"
510 PRINT"Printing";TAB(12)"Number";TAB(21)"MM|DD";TAB(63)"Possible => ";TR
520 IF EOF(1) THEN 760
530 LINE INPUT#1,A$
540 GOSUB 870
550 IF INKEY$=CHR$(27) THEN 760
560 HS$=LEFT$(A$,1):XR$=MID$(A$,4,2)+":"+MID$(A$,7,2)
570 DR$=MID$(A$,10,3):FL$=MID$(A$,14,8):EN$=MID$(A$,22,3)
580 SZ$=MID$(A$,38,3)+"k":DE$=MID$(A$,43,2)+" "+MID$(A$,46,2)
590 UN$=MID$(A$,58,30)
600 IF CHEK<VAL(M$) THEN GOSUB 880
610 IF CHEK>=VAL(M$) THEN 620 ELSE 520
620 IF HS$=HS1$ OR HS$=HS2$ THEN 520
630 IF DR$=DR1$ OR DR$=DR2$ THEN 520
640 IF EN$=EN0$ OR EN$=EN1$ OR EN$=EN2$ OR EN$=EN3$ THEN 520
650 IF EN$=EN4$ OR EN$=EN5$ OR EN$=EN6$ OR EN$=EN7$ OR EN$=EN8$ THEN 520
660 IF EN$=EN9$ OR EN$=EN10$ THEN 520
670 IF UN$=SYSP$ THEN 520
680 T=T+1
690 IF CHEK>=VAL(M$) THEN PRINT#2,FL$+"."+EN$;TAB(15);SZ$+" "+" by => ";UN$;
700 PRINT#2,TAB(52)" on =>";DE$
710 OK=OK-1:TD=TD+1
720 PRINT;FL$;
730 PRINT TAB(12);USING"######";T;
740 PRINT TAB(21);MID$(A$,43,2)+"|"+MID$(A$,46,2);:PRINT CHR$(13);
750 GOTO 520
760 LAST=1:GOSUB 820
770 PRINT"Records written to disk...: ";:PRINT USING"###### ";TD
780 PRINT:PRINT"Output file contains......: ";
790 PRINT USING"######";(LOC(2)*128)+((T*2)+1);
800 PRINT" Bytes":PRINT:PRINT
810 CLOSE:END
820 PRINT CLS$
830 IF LAST=1 THEN 860
840 PRINT LOGO$:PRINT CPRT$:PRINT DEAD$;TAB(63);TYPE$
850 PRINT:PRINT:PRINT:RETURN
860 PRINT LOGO$:PRINT CPRT$;TAB(63);TYPE$:GOTO 850
870 CHEK=VAL(MID$(A$,43,2)):RETURN
880 IF TR>1 THEN 890 ELSE 900
890 PRINT"Please wait...";TAB(21);MID$(A$,43,2)+"|"+MID$(A$,46,2);
895 PRINT CHR$(13);:RETURN
900 PRINT"Discarding => ";:PRINT MID$(A$,43,2)+" | ";
910 PRINT MID$(A$,46,2)+"          ";:PRINT CHR$(13);:RETURN
920 IF ERR=53 THEN PRINT"Missing File! Check DIR!":RESUME 810