10 REM - Printer preset program - for EPSON RX-80 Printer
20 REM
30 REM - Written by:  Barron F. McIntire III
40 REM                3400 S. Greeley hwy #8
50 REM                Cheyenne, Wyoming  82007
60 REM                27 August 1983
70 REM
80 PRINT CHR$(26)
90 PRINT TAB(15)"***** PRINTER PRE-SET PROGRAM v1.0 *****":PRINT
100 PRINT "This program will allow the operator to pre-set certain printer"
110 PRINT "states.  The printer will remain in these states until the printer"
120 PRINT "power is recycles, or the printer is directed into another state"
130 PRINT "by program control.":PRINT
140 PRINT "The following options are available;":PRINT
150 PRINT "  1. Printer initialization            12. Ignore paper end detector"
160 PRINT "  2. Elite-sized character setting     13. Unidirectional printing"
170 PRINT "  3. Pica-sized character setting      14. 7/72 inch line spacing"
180 PRINT "  4. Enlarged mode                     15. 1/16 inch line spacing"
190 PRINT "  5. Enlarged mode (1 line only)       16. 1/8 inch line spacing"
200 PRINT "  6. Condensed mode                    17. n/72 inch line spacing"
210 PRINT "  7. Emphasized/enlarged mode          18. n/216 inch line spacing"
220 PRINT "  8. Emphasized mode                   19. Form length setting"
230 PRINT "  9. Double-strike mode                20. Skip over perforation"
240 PRINT " 10. Alternate character set (italics) 21. Right margin setting"
250 PRINT " 11. Underline mode                    22. Left margin setting"
260 PRINT:INPUT "Enter desired option";OPT
270 IF OPT<1 OR OPT<>INT(OPT) THEN 260
280 IF OPT<23 THEN 320
290 PRINT "EXIT PROGRAM (Y/N)?";
300 A$=INKEY$:IF A$="Y" OR A$="N" THEN 310 ELSE 300
310 IF A$="Y" THEN SYSTEM ELSE 260
320 ON OPT GOTO 330,350,370,390,410,430,450,470,490,510,530,550,570,590,610,

                630,650,680,710,800,830,860
330 LPRINT CHR$(27);"@";
340 GOTO 880
350 LPRINT CHR$(27);"M";
360 GOTO 880
370 LPRINT CHR$(27);"P";
380 GOTO 880
390 LPRINT CHR$(27);"W";CHR$(1);
400 GOTO 880
410 LPRINT CHR$(14);
420 GOTO 880
430 LPRINT CHR$(15);
440 GOTO 880
450 LPRINT CHR$(27);"E";CHR$(27);"W";CHR$(1);
460 GOTO 880
470 LPRINT CHR$(27);"E";
480 GOTO 880
490 LPRINT CHR$(27);"G";
500 GOTO 880
510 LPRINT CHR$(27);"4";
520 GOTO 880
530 LPRINT CHR$(27);"-";CHR$(1);
540 GOTO 880
550 LPRINT CHR$(27);"8";
560 GOTO 880
570 LPRINT CHR$(27);"U";CHR$(1);
580 GOTO 880
590 LPRINT CHR$(27);"1";
600 GOTO 880
610 LPRINT CHR$(27);"2";
620 GOTO 880
630 LPRINT CHR$(27);"0";
640 GOTO 880
650 INPUT "Enter n/72 line spacing required";N
660 LPRINT CHR$(27);"A";CHR$(N);
670 GOTO 880
680 INPUT "Enter n/216 line spacing required";N
690 LPRINT CHR$(27);"3";CHR$(N);
700 GOTO 880
710 INPUT "Specify setting by lines (1) or inches (2)";S
720 IF S<>1 AND S<>2 THEN 710
730 ON S GOTO 740,770
740 INPUT "Enter number of lines";N:IF N<1 OR N>127 THEN 740 ELSE 750
750 LPRINT CHR$(27);"C";CHR$(N);
760 GOTO 880
770 INPUT "Enter number of inches";N:IF N<1 OR N>22 THEN 770 ELSE 780
780 LPRINT CHR$(27);"C";CHR$(0);CHR$(N);
790 GOTO 880
800 INPUT "Enter number of lines to be skipped";N:IF N<1 OR N>127 THEN 800
810 LPRINT CHR$(27);"N";CHR$(N);
820 GOTO 880
830 INPUT "Enter number of characters required in line (P=80, E=96, C=137)";N
840 LPRINT CHR$(27);"Q";CHR$(N);
850 GOTO 880
860 INPUT "Enter column in which to start left margin";N
870 LPRINT CHR$(27);"l";CHR$(N);
880 PRINT:PRINT "Another option (Y/N)?"
890 A$=INKEY$:IF A$="Y" OR A$="N" THEN 900 ELSE 890
900 IF A$="Y" THEN 140 ELSE SYSTEM
910 END