100 FOR LOOP=1 TO 24:PRINT:NEXT LOOP
200 PRINT TAB(28) "DESKMASTER install program"
300 PRINT TAB(28) "Version 1, Copyright 1983":PRINT:PRINT
400 PRINT TAB(31)"by George Sofaly":FOR LOOP=1 TO 10:PRINT:NEXT LOOP:FOR DELAY=1 TO 1500:NEXT DELAY:FOR LOOP=1 TO 24:PRINT:NEXT LOOP
600 PRINT TAB(7)"Numerous terminals are listed below with their clear screen control"
700 PRINT TAB(7)" codes given. If your terminal type is listed, press it's letter and"
1200 PRINT TAB(7)"the proper parameters will be entered for you automatically. If it"
1300 PRINT TAB(7)"is NOT listed then press letter 'G' and you will  be asked to give"
1400 PRINT TAB(7)"the proper coding sequence. Please check your manual!
1500 FOR LOOP=1 TO 7:PRINT:NEXT LOOP:PRINT TAB(5)"Press any key";:RESPONSE$=INPUT$(1):FOR LOOP=1 TO 12:PRINT:NEXT LOOP
1600 PRINT:CL1$="":CL$=""
1700 PRINT TAB(15)"A.  ADM-3 (12)                       H.  KAYPRO II (26)"
1800 PRINT TAB(15)"B.  ADDS 100 (12)                    I.  OSBORNE I (26)"
1900 PRINT TAB(15)"C.  HAZELTINE (126,28)               J.  SOL (11)"
2000 PRINT TAB(15)"D.  HEATHKIT (27,69)                 K.  SOROC (27,42)"
2100 PRINT TAB(15)"E.  INFOTON (12)                     L.  SWTP (28,18)"
2200 PRINT TAB(15)"F.  INTERTUBE (12)                   M.  TELEVIDEO (27,42)"
2300 PRINT TAB(15)"G.  NONE                             N.  ZENITH (27,69)"
2400 FOR LOOP=1 TO 10:PRINT:NEXT LOOP:PRINT TAB(10)"Please select (A,B,C,D,E,F,G,H,I,J,K,L,M,N) your terminal type.";:RESPONSE$=INPUT$ (1)
2410 IF ASC(RESPONSE$)<65 OR ASC(RESPONSE$)>78 THEN PRINT:PRINT:PRINT:GOTO 1600
2415 IF RESPONSE$="G" THEN PRINT:PRINT:PRINT:GOTO 2500
2420 GOTO 10000
2500 PRINT:PRINT TAB(10)"Enter control codes now.   Press <RET> when finished."
2600 FOR LOOP=1 TO 5:PRINT LOOP ;:INPUT;": ",RESPONSE$(LOOP)
2700 PRINT:IF RESPONSE$(LOOP)="" THEN 2900 ELSE CL1$=CHR$(VAL(RESPONSE$(LOOP))):CL$=CL$+CL1$
2800 NEXT LOOP
2900 PRINT CL$:FOR DELAY = 1 TO 500:NEXT DELAY:PRINT TAB(10)"The program should have just cleared the screen if the codes"
3000 PRINT TAB(15)"were entered properly. Did the screen clear (Y/N)?":RESPONSE$=INPUT$ (1)
3100 IF RESPONSE$="N"OR RESPONSE$="n" THEN PRINT:PRINT:PRINT TAB(28)"PLEASE START OVER!":FOR DELAY=1 TO 1000:NEXT DELAY:CLEAR:GOTO 100
3400 BEL$=CHR$(7):PRINT CL$:PRINT:PRINT:PRINT:PRINT:PRINT
3600 PRINT CL$:INPUT"Enter number of rows on your screen (E.G.,16,24): ",CONROW
3700 PRINT:INPUT"Enter number of columns on your screen (E.G.,64,80): ",CONCOLUM
3800 PRINT:INPUT"Enter printer line width (E.G.,80,132): ",PRNCOLUM
3900 PRINT:PRINT"Enter default disk drive (A,B,C,D,E,F,G): ";
4000 DEFALTDISK$=INPUT$(1)
4100 IF ASC(DEFALTDISK$)>64 AND ASC(DEFALTDISK$)<72 THEN DEFALTDISK$=DEFALTDISK$+":":PRINT DEFALTDISK$:GOTO 4300
4200 PRINT BEL$ CHR$(13);:GOTO 3900
4300 '
4400 PRINT CL$:PRINT"Working...            Please wait"
4500 BIOSB=(PEEK(2)*256)+PEEK(1):PRNLOC=BIOSB+13:CONLOC=BIOSB+10
4600 PBYTE=PEEK(PRNLOC):CBYTE=PEEK(CONLOC):C=CBYTE:F=CBYTE:PBYTE1=PEEK(PRNLOC+1):CBYTE1=PEEK(CONLOC+1)
4700 C1=CBYTE1:F1=PBYTE1
4800 FOR I%=16000 TO 25000
4900 IF PEEK(I%)=CBYTE AND PEEK(I%+1)=PEEK(CONLOC+1) THEN 5400
5000 NEXT I%
5100 PRINT BEL$:PRINT"NOTICE!! DESKMASTER mayl not function properly with your printer!"
5200 PRINT"All screen operations should be okay.":PRINT
5300 PRINT:PRINT:PRINT"Press any key ";:RESPONSE$=INPUT$(1)
5400 LOPOC=I%
5500 PRINT CL$:PRINT"Please wait...   Writing data to disk ";
5600 PRINT CHR$(34) "A:" CHR$(34) "..."
5700 OPEN "O",#1,"PARA.DAT":C=ASC(CL$)
5900 WRITE #1,C,CONROW,CONCOLUM,PRNCOLUM,LOPOC,PBYTE,CBYTE
6300 CLOSE #1
6400 IF DEFALTDISK$="A:" THEN 6700
6500 PRINT:PRINT "Please wait... writing data to disk.";DEFALTDISK$
6600 OPEN "O",#1,DEFALTDISK$+"PARA.DAT":WRITE #1,CL$,CONROW,CONCOLUM,PRNCOLUM,LOPOC,PBYTE,CBYTE:CLOSE #1
6700 PRINT CL$:PRINT"Writing complete. Thank you."
6800 CHAIN "DESK.BAS"
10000 IF RESPONSE$="A" THEN CL$=CHR$(12):GOTO 2900
10010 IF RESPONSE$="B" THEN CL$=CHR$(12):GOTO 2900
10020 IF RESPONSE$="C" THEN CL$=CHR$(126)+CHR$(28):GOTO 2900
10030 IF RESPONSE$="D" THEN CL$=CHR$(27)+CHR$(69):GOTO 2900
10040 IF RESPONSE$="E" THEN CL$=CHR$(12):GOTO 2900
10050 IF RESPONSE$="F" THEN CL$=CHR$(12):GOTO 2900
10060 IF RESPONSE$="H" THEN CL$=CHR$(26):GOTO 2900
10070 IF RESPONSE$="I" THEN CL$=CHR$(26):GOTO 2900
10080 IF RESPONSE$="J" THEN CL$=CHR$(11):GOTO 2900
10090 IF RESPONSE$="K" THEN CL$=CHR$(27)+CHR$(42):GOTO 2900
10100 IF RESPONSE$="L" THEN CL$=CHR$(28)+CHR$(18):GOTO 2900
10110 IF RESPONSE$="M" THEN CL$=CHR$(27)+CHR$(42):GOTO 2900
10120 IF RESPONSE$="N" THEN CL$=CHR$(27)+CHR$(69):GOTO 2900