10 '************************************************************
20 '*                  COLLECTION REPORT                       *
30 '*  COLLECT.BAS                             8/28/82         *
40 '************************************************************
45 REVERSE$=CHR$(27)+CHR$(71)+CHR$(52)'*******OK FOR TELEVIDEO 910
50 PRINT CHR$(26)
60 PRINT REVERSE$; TAB(31)"COLLECTION  REPORT"
70 PRINT STRING$(79,"-")
80 INPUT"WHAT MONTH IS THIS REPORT BEING PREPARED FOR ";MO$
81 BB%=LEN(MO$)
82 FOR X%=1 TO BB%
83 IF MID$(MO$,X%,1)<CHR$(65) OR MID$(MO$,X%,1)>CHR$(90) THEN PRINT"BAD DATE - ENTER ALPHA DATA ONLY - NO NUMBERS":GOTO 80
84 NEXT X%
85 MONTH$=LEFT$(MO$,3)
90 OPEN"I",1,"DATE.DAT"
100 INPUT#1,Y9$,W$,X$,Y$:CLOSE 1
110 GOSUB 150:GOTO 200
150 TB=(80-LEN(W$))/2:TB=INT(TB)
160 LPRINT TAB(TB);W$
170 LPRINT TAB(31);"COLLECTION  REPORT"
175 TA=(71-LEN(MO$))/2:TA=INT(TA):TITLE$="MONTH OF "+MO$
180 LPRINT TAB(TA);TITLE$
190 LPRINT:LPRINT"SPACE  RENT   UTILITIES  MISC.CHGS.  TOTAL DUE  DATE PAID  AMOUNT  REC.BY  B/F"
195 LPRINT STRING$(79,"-"):LPRINT:LC=6
196 RETURN
200 OPEN"I",1,"REC.DAT"
205 OPEN"O",4,MONTH$+".DAT"
210 IF EOF(1) GOTO 500
215 INPUT#1,A1,KN#,A2,A3,A4,A5$,A6,A7#,A8,A9,B1,B2#,B3,B4
216 PRINT#4,A1;",";KN#;",";A2;",";A3;",";A4;",";A5$;",";A6;",";A7#;",";A8;",";A9;",";B1;",";B2#;",";B3;",";B4 
221 B4=B4*100
222 A7#=INT(A7#*100+.5)/100:PRINT A7#
230 LPRINT USING"#####  ###.##    ###.##     ###.##     ###.##";KN#;A9/100;A7#;B2#/100+B4#;((A9+B2#)/100)+B4#+A7#;
240 LPRINT"    .........  .....  .....  ....."
245 T1=T1+A9:T2=T2+A7#:T3=T3+(B2#/100)+B4#
246 LPRINT
250 LC=LC+2
260 IF LC<54 GOTO 210
270 FOR XX%=LC TO 65:LPRINT:NEXT XX%
280 LC=0:GOSUB 150
290 GOTO 210
500 CLOSE:LPRINT:LPRINT STRING$(79,"=")
510 LPRINT"TOTALS:"
511 T2=INT(T2*100+.5)/100
520 LPRINT USING"     #####.##   ####.##    ####.##   #####.##";T1/100;T2;T3;(T1/100)+T2+T3
530 LC=LC+2
540 FOR XX%=LC TO 65:LPRINT:NEXT XX%
550 RESET:RUN"MENU"