; MM530PAT.ASM   PATCH FOR MASMENU.COM VERSION 5.30
; 6/4/86 GSD
;
; THIS PATCH:
;
;	1. ENSURES THAT THE 25th LINE ON THE SCREEN IS ERASED
;	2. forces a Warm Boot so that the $$$.SUB file will
;	   be correctly processed.
;	3. ASSEMBLES WITH DRI'S MAC ASSEMBLER
;
; USE DDT TO PATCH MASMENU.COM:
;
; A>DDT MASMENU.COM
; NEXT PC
; 3CC0 0100
; #IMM530PAT.HEX
; #R
; #G0
; A>SAVE 59 MM530PAT.COM
;
;
BDOS	equ	0005H	; BDOS ENTRY
ESC	equ	01BH	; ASCII ESCAPE CHARACTER
;
	ORG 	13DH	; ID STRING
	DB 	'5.30'

	ORG 	100H	; start of TPA
;
	JMP	inisub	; branch to patch code
;
	org	32e8h	; old exit routine

	jmp	unisub

	org	32bdH	; end of program pointer

	DW	ENDPRG	; change pointer to protect patch

	ORG 	3bb9H	; start of patch area
;
inisub:	lxi	d,line25	; 25 line screen message
	mvi	c,9		; BDOS PRINT STRING FUNCTION
	call	BDOS		; disable the status line
	jmp	32bfH		; execute masmenu

;
unisub:
	lxi	d,line24	; 24 line screen message
	mvi	c,9		; BDOS PRINT STRING FUNCTION
	call	BDOS		; enable the status line
	rst	0		; Warm Boot

line25:	DB	ESC,'C7$'
line24:	DB	ESC,'B7$'
;
ENDPRG	equ	$		; end marker
;
	END