10 REM  AAII PROGRAM-4 OPTIONS ON FUTURES
20 DEF FN B(X) = INT (X * 10000) / 10000
30 PRINT CHR$(26)
40 PRINT "THIS PROGRAM EVALUATES FUTURE CALLS"
50 PRINT "AND PUTS WITH SAME EXERCISE PRICE"
60 PRINT "AND EXPIRATION DATE"
70 PRINT "FIGURES IN ( ) ARE EXAMPLES ON INPUT FORM"
80 PRINT
90 PRINT "FUTURES PRICE-DECIMAL(70.5)"
100 INPUT P
110 PRINT "ASD-- VOLATILTY(.35)"
120 INPUT V9
130 PRINT "RISK FREE INTEREST RATE%(12)"
140 INPUT R9
150 R9 = R9 /100
160 V = V9 / 19.1
170 R = R9 /365
180 E = 2.71828
190 DEF FN A(Z) = 1 - .5 * (1 + .1969 * Z + .1152 * Z ^ 2 + .00034 * Z ^ 3 + .0195 * Z ^ 4) ^ ( - 4)
200 PRINT "OPTION EXERCISE PRICE (70)"
210 INPUT S
220 PRINT "DAYS (CALENDAR) UNTIL EXPIRATION"
230 INPUT T
240 PRINT
250 PRINT
260 P1 = P
270 D1 = (LOG(P1 / S) + (.5 * V ^ 2) * T) / (V * T ^ (.5))
280 D2 = (LOG(P1 / S) - (.5 * V ^ 2) * T) / (V * T ^ (.5))
290 IF D1 >= 0 THEN 320
300 A = 1 - FN A(ABS(D1))
310 GOTO 330
320 A = FN A(D1)
330 IF D2 >= 0 THEN 360
340 B = 1 - FN A(ABS(D2))
350 GOTO 370
360 B = FN A(D2)
370 V6 = (P1 * A - S * B) * E ^ (- R * T)
380 P2 = P1
390 D3 = (LOG(S / P2) - (.5 * V ^ 2) * T) / (V * T ^ (.5))
400 IF D3 >= 0 THEN 430
410 A1 = 1 - FN A(ABS(D3))
420 GOTO 440
430 A1 = FN A(D3)
440 V1 = V6 + (S * E ^ ( - R * T)) - P1 * E ^ ( - R * T)
450 PRINT "PRICE=";P;"  EX-PRICE= ";S
460 PRINT "INTEREST RATE= ";R9
470 PRINT "ASD= "; FN B(V9);"  TIME LEFT=  ";T
480 PRINT
490 PRINT "CALL OUTPUT"
500 PRINT
510 PRINT "ESTIMATED VALUE="; FN B(V6)
520 PRINT "DELTA VALUE="; FN B(A)
530 PRINT
540 PRINT "PUT OUTPUT"
550 PRINT
560 PRINT "ESTIMATED VALUE="; FN B(V1)
570 PRINT "DELTA VALUE=";FN B(A1)
580 PRINT
590 PRINT "ANOTHER OPTION SAME COM(1) OR NOT(2)"
600 INPUT G4
610 IF G4 = 1 THEN 200
630 END