;==RDDTMOD.ASM===H WEINSTEIN=== 8303200530 =================
;
; DDT is a trademark of Digital Research,Inc.  DDT.COM is a
; copyright program of Digital Research, Inc.  Do not distri-
; bute modified copies of DDT.COM.  Do not exceed the
; ridiculous limitations of your license agreement with
; Digital Research, Inc. 
;
;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
;\\ Copyright 1983 H Weinstein, San Diego CA 92128.   \\
;\\	All rights reserved.  May be copied for     \\
;\\	personal, non-commercial use only.          \\
;\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
;
; The following is for personal experimentation purposes only.
;
; This is a modification of DDT.COM version 2.2 which
; permits the operator to determine where DDT will run
; between the limits of 1500h and (BDOS and 00FFh)-1000h.
;
; This helps to keep DDT out of the way of something you
; might want to look at (e.g., CCP) which would not be
; possible under standard DDT.
;
; -  -  -  -  -  -  -  -  -  -  -  -  -  -  -  -  -  -  -  -
;
; RECIPE:
;
;	1. Change the name of this file to RDDTMOD.ASM
;	2. Assemble it to obtain a file named RDDTMOD.HEX
;	3. Place the disk with this hex file in drive A:
;	4. If DDT is on the same disk, go to step 5 else
;	   mount the disk with DDT in drive B:
;	5. Invoke DDT
;	6. Enter the following series of commands after
;	   receiving the DDT prompt. For the purpose of
;	   this recipe, DDT's messages are in square
;	   brackets.  You enter the commands which are NOT
;	   so enclosed, following each with a RETURN or
;	   ENTER keystroke.  Here is the series:
;
;		[-] F100,2000,0
;		[-] IDDT.COM
;
; NOTE WELL: If your DDT disk is in drive B: then enter the
;            following, else skip to the line following 
;	     NOTE 2.
;
;		[-] S5C
;		[005C 00] 2
;		[005D 44] .
;
; NOTE 2: See above
;		[-] R
;		[NEXT  PC]
;		[1500 0000]
;		[-] G0
;
;		A>SAVE 20 RDDT.COM
;
; When the system prompt appears on the screen, RDDT is 
;	available for your experimental use.  It is self-
;	prompting. All you will need to remember is that
;	when you respond with, say, page A6, the TPA from
;	0A600h through 0B5FFh will be in use by the program.
;
; -  -  -  -  -  -  -  -  -  -  -  -  -  -  -  -  -  -  -  -
;
	org 12Dh
	db 13,10,'R'
	org 143h
	db 2Dh
;
	org 14Bh
	jmp 1400h
;
	org 1400h
	push b
	lda 7
	sui 10h
	push psw
	mov h,a
	rrc ! rrc ! rrc ! rrc
	call bcd2asc
	sta max
	mov a,h
	call bcd2asc
	sta max+1
	call max$msg
	db 13,10,10
	db 'Enter HEX page number:',13,10,9
	db 'NOT less than 15h nor more than '
max	db 'XXh.',13,10,10
	db '<CR> gives maximum default.  SELECTION:  $'
bcd2asc	ani 0Fh
	adi 90h
	daa
	aci 40h
	daa
	ret
accept	mov b,a
	cpi 0Ah
	mvi a,0
	rc
	mov a,b
	cpi 11h
	mvi a,0FFh
	rc
	mov a,b
	sui 7
	mov b,a
	cpi 10h
	mvi a,0
	rc
	mvi a,0FFh
	ret
max$msg	mvi c,9
	pop d
	call 5
	mvi c,1
	call 5
	cpi 13
	jz default
	sui 30h
	call accept
	ora a
	jnz 100h
	mov a,b
	sta max
	mvi c,1
	call 5
	sui 30h
	call accept
	ora a
	jnz 100h
	mov a,b
	sta max+1
	lda max
	add a ! add a ! add a ! add a
	lxi h,max+1
	add m
	mov b,a
	cpi 15h
	jc 100h
	pop psw
	cmp b
	jc 100h
	mov a,b
	pop b
	jmp 151h
;
default pop psw
	pop b
	jmp 151h
	end