1 '	FILENAME: TXT2HLP.BAS

	VERSION:  1.2

	AUTHOR:   LEEMAC JUN 87


	Lee McEwen, 2426 Stone Haven Ct, Orange Park, FL 32065


2 '	TEXT TO HELP FILE CONVERTER.


	This program is self-documenting, with the accompanying file,

	TXT2HLP.HLP.  It is used to convert text files to help files.


3 '	Copyright (c) 1987.  All rights reserved.  Non-commercial use

	and distribution is authorized with following reservations:


	1) The following files are distributed with the program:
4 '		a) TXT2HLP.HLP:  The menu and help file for this program.

		b) TXT2HLP.TXT:  The wordprocessor source file for the

				 help file above.

	2) The original author's name and address remain all files.
5 '	3) There be no charge for distribution other than postage costs,

	   or on-line charges in the case of electronic distribution.



100	GOSUB 60000
110	GOSUB 60010
120	PRINT CLS$:

	X=1:

	GET#3,X:

	X=VAL(SN$):

	Y=X+VAL(SL$):

	WHILE+ X<Y:

		GET#3,X:

		PRINT TX$:

		X=X+1:

	WEND
130	INLEN=1:

	GOSUB 60030:

	ON VAL(IN$) GOSUB 1000,2000,3000,4000,5000,6000,7000,8000,9000:

	GOTO 110


1000	D=0:

	GOSUB 12000:

	IF IN$="Q"

		THEN	RETURN

		ELSE	D=1:

			GOSUB 12000:

			IF IN$="Q"

				THEN 	RETURN
1010	IF INFILE$=OUTFILE$

		THEN	PRINT CLS$:

			PRINT:

			PRINT BELL$:

			PRINT "The output file must have a different name as":

			PRINT "the input file!  Please repeat input.":

			PRINT:

			PRINT "Any key to continue.":

			IN$=INPUT$(1):

			GOTO 1000
1020	PRINT CLS$:

	PRINT "You have selected:":

	PRINT:

	PRINT "Input file:  ";INFILE$:

	PRINT "Output file: ";OUTFILE$
1030	PRINT:

	PRINT "Are these correct? (Y/N/Q) ";:

	INLEN=1:

	GOSUB 60030:

	IF IN$="N"

		THEN	1000:

		ELSE	IF IN$="Q"

				THEN	RETURN:

				ELSE	IF IN$="Y"

						THEN	PRINT:

							PRINT:

						ELSE	1030
1040	OPEN "I",2,INFILE$:

	FOR J=1 TO 100:

		PNUM$(J)="":

		PLEN$(J)="":

		PTOPIC$(J)="":

	NEXT J:

	X=1:

	Y=0:

	Z=1:

	WHILE+ NOT(EOF(2)):

		LINE INPUT#2,A$
1050		IF LEN(A$)<3

			THEN A$=A$+" "
1060		IF LEFT$(A$,2)="\T" OR LEFT$(A$,2)="\t"

			THEN	PNUM$(X)=STR$(Z):

				PLEN$(X)=STR$(Y):

				PTOPIC$(X)=MID$(A$,3):

				X=X+1:

				Y=0:

			ELSE	Y=Y+1:

				Z=Z+1:

				
1070	WEND:

	CLOSE:

	X=X-1:

	PRINT "Topic: Record: Lines: Title:":

	PRINT "-----  ------  -----  -----"
1080	PNUM$(X+1)="":

	PLEN$(X+1)="":

	PLEN$(X+1)=" 00":

	PTOPIC$(X)="End of file."
1090	FOR K=1 TO X:

		PNUM$(K)=STR$(VAL(PNUM$(K))+X):

		PLEN$(K)=PLEN$(K+1):

		PRINT CHR$(7);
1100		OT$=RIGHT$(STRING$(5,32)+STR$(K),5)+"  ":

		OT$=OT$+RIGHT$(STRING$(6,32)+PNUM$(K),6)+"  "
1110		OT$=OT$+RIGHT$(STRING$(5,32)+PLEN$(K),5)+"  ":

		OT$=OT$+LEFT$(PTOPIC$(K)+STRING$(48,32),48):

		PRINT OT$:

	NEXT K
1120	IN=FRE(0):

	PRINT:

	PRINT "Press any key to continue.":

	IN$=INPUT$(1):

	PRINT CLS$
1130	OPEN "R",1,OUTFILE$,78:

	OPEN "I",2,INFILE$:

	FIELD 1, 78 AS TXT$:

	FIELD 1, 5 AS SNUM$, 5 AS SLEN$, 48 AS STOPIC$
1140	LSET TXT$="":

	X=1:

	WHILE+ PNUM$(X)<>"":

		LSET SNUM$=PNUM$(X):

		LSET SLEN$=PLEN$(X):

		LSET STOPIC$=PTOPIC$(X):

		PUT#1,X:

		X=X+1:

	WEND:

	X=X-1
1150	WHILE+ NOT(EOF(2)):

		X=X+1:

		LINE INPUT#2,A$:

		LSET TXT$=A$:

		IF LEFT$(TXT$,2)="\T" OR LEFT$(TXT$,2)="\t"

			THEN	X=X-1:

			ELSE	PUT#1,X:

				PRINT TXT$
1160	WEND:

	CLOSE:

	IN=FRE(0):

	RETURN


2000	D=0:

	GOSUB 12000:

	IF IN$="Q"

		THEN	RETURN
2010	OPEN "R",1,INFILE$,78:

	FIELD 1, 78 AS TXT$:

	GOSUB 11000:

	IF X=0

		THEN	2030:

		ELSE	PRINT CLS$:

			PRINT "Enter 'Q' to Quit.":

			PRINT
2020	INPUT "WHICH RECORD";IN$:

	GOSUB 60040:

	IF LEFT$(IN$,1)="Q"

		THEN	2030:

		ELSE	X=VAL(IN$):

			GET#1,X:

			PRINT TXT$:

			GOTO 2020
2030	CLOSE:

	RESET:

	PRINT:

	PRINT "Press any key to continue.":

	A$=INPUT$(1):

	RETURN


3000	D=0:

	GOSUB 12000:

	IF IN$="Q"

		THEN	RETURN
3010	OPEN "R",1,INFILE$,78:

	FIELD #1,78 AS TXT$:

	FIELD #1,5 AS SNUM$,5 AS SLEN$,48 AS STOPIC$:

	GOSUB 11000:

	IF X=0

		THEN	3110:

		ELSE	X=1
3020	PRINT CLS$:

	PRINT "The following is a list of topics in this file:":

	PRINT:

	GET#1,X:

	WHILE VAL(SLEN$)>0:

		PRINT RIGHT$(STRING$(3,32)+STR$(X),3);")   ";STOPIC$:

		X=X+1:

		GET#1,X:

	WEND
3030	PRINT BELL$:

	PRINT "Enter number beside topic you wish to read, or 'Q' to quit. ";:

	INLEN=2:

	GOSUB 60030:

	IF IN$="Q"

		THEN	3110
3040	IF VAL(IN$)<1 OR VAL(IN$)>X-1

		THEN	3030:

		ELSE	X=VAL(IN$)
3050	GET#1,X:

	Y=VAL(SNUM$):

	Z=VAL(SLEN$)
3060	PRINT CLS$:

	K=Y:

	WHILE+ K<Y+Z:

		GET#1,K
3070		IF LEFT$(TXT$,2)="\S" OR LEFT$(TXT$,2)="\s"

			THEN	PRINT BELL$:

				PRINT "Any key to continue, or 'Q' to quit.";:

				IN$=INPUT$(1):

				GOSUB 60040:

				IF IN$="Q"

					THEN	3100:

					ELSE	PRINT CLS$:

						GOTO 3090
3080		PRINT TXT$
3090		K=K+1:

	WEND:

	PRINT BELL$:

	PRINT "End of topic.  Any key to continue. ";:

	IN$=INPUT$(1)
3100	X=1:

	GOTO 3020
3110	CLOSE:

	RETURN


4000	PRINT CLS$:

	X=2
4010	PRINT "Help is available for the following topics:":

	PRINT:

	GET#3,X:

	WHILE+ VAL(SL$) > 0:

		PRINT RIGHT$(STRING$(2,32)+STR$(X-1),2);")   ";ST$:

		X=X+1:

		GET#3,X:

	WEND
4020	PRINT BELL$:

	PRINT "Enter number beside topic you wish help on, or 'Q' to quit. ";:

	INLEN=2:

	GOSUB 60030:

	IF IN$="Q"

		THEN	4110
4030	IF VAL(IN$)<1 OR VAL(IN$)>X-1

		THEN	4020:

		ELSE	X=VAL(IN$)
4040	GET#3,X+1:

	Y=VAL(SN$):

	Z=VAL(SL$)
4050	PRINT CLS$:

	K=Y:

	WHILE+ K<Y+Z:

		GET#3,K
4060		IF LEFT$(TX$,2)="\S" OR LEFT$(TX$,2)="\s"

			THEN	PRINT BELL$:

				PRINT "Any key to continue, or 'Q' to quit.";:

				IN$=INPUT$(1):

				GOSUB 60040:

				IF IN$="Q"

					THEN	4100:

					ELSE	PRINT CLS$:

						GOTO 4090
4070		IF LEFT$(TX$,1)="\"

			THEN 4090
4080		PRINT TX$
4090		K=K+1:

	WEND:

	PRINT BELL$:

	PRINT "End of topic.  Any key to continue. ";:

	IN$=INPUT$(1)
4100	GOTO 4000
4110	CLOSE:

	RETURN


5000	D=0:

	GOSUB 12000:

	IF IN$="Q"

		THEN	5040
5010	X=INSTR(INFILE$,"."):

	IF X=0

		THEN	INFILE$=INFILE$+".":

			GOTO 5010
5020	A1$=LEFT$(INFILE$,2):

	A2$=MID$(INFILE$,3,X-3):

	A3$=MID$(INFILE$,X+1,LEN(FILE$)):

	A2$=A2$+LEFT$("????????",8-LEN(A2$)):

	A3$=A3$+LEFT$("???",3-LEN(A3$)):

	INFILE$=A1$+A2$+"."+A3$
5030	PRINT:

	PRINT:

	PRINT:

	FILES INFILE$:

	PRINT:

	PRINT:

	PRINT "Any key to continue.";:

	A$=INPUT$(1)
5040	RETURN


6000	PRINT CLS$:

	RESET:

	PRINT "Place disk in drive and press any key to continue. ";:

	IN$=INPUT$(1):

	RESET:

	RETURN


7000	D=0:

	GOSUB 12000:

	IF IN$="Q"

		THEN	RETURN

		ELSE	D=1:

			GOSUB 12000:

			IF IN$="Q"

				THEN	RETURN
7010	PRINT CLS$:

	PRINT "You have selected:":

	PRINT:

	PRINT "Rename ";INFILE$;" to ";OUTFILE$
7020	PRINT:

	PRINT "Are these correct? (Y/N/Q) ";:

	INLEN=1:

	GOSUB 60030:

	IF IN$="N"

		THEN	7000:

		ELSE	IF IN$="Q"

				THEN	RETURN

				ELSE	IF IN$="Y"

						THEN	PRINT:

							PRINT:

						ELSE	7020
7030	NAME INFILE$ AS OUTFILE$:

	RETURN


8000	D=2:

	GOSUB 12000:

	IF IN$<>"Q"

		THEN	PRINT:

			PRINT:

			PRINT "KILL ";OUTFILE$;"?";BELL$;BELL$:

			PRINT "Are you sure? (Y/N) ";:

			INLEN=1:

			GOSUB 60030:

			IF IN$="Y"

				THEN	KILL OUTFILE$
8010	RETURN


9000	CLOSE:

	RESET:

	PRINT CLS$:

	PRINT:

	PRINT:

	PRINT "Program terminated.":

	END


'----SUBROUTINES FOLLOW----


10000	IF ERR=53

		THEN	PRINT BELL$:

			PRINT BELL$;"File not found":

			PRINT BELL$:

			RESUME NEXT
10010	PRINT "UNIDENTIFIED ERROR!  ERROR LINE:";ERL,"ERROR NUMBER:";ERR:

	STOP


11000	X=1:

	WHILE+ X>0:

		GET#1,X:

		IF TXT$=STRING$(78,0)

			THEN	X=X+1:

			ELSE	X=-1
11010		IF X=10

			THEN	PRINT:

				PRINT:

				PRINT "File not found.":

				CLOSE:

				KILL INFILE$:

				X=0
11020	WEND:

	RETURN


12000	PRINT CLS$:

	FILE$=INFILE$:

	D$="input":

	IF D=1

		THEN	FILE$=OUTFILE$:

			D$="output":

		ELSE	IF D=2

			THEN FILE$=OUTFILE$:

			D$="KILL"
12010	IF FILE$=""

		THEN	FILE$="A:NONAME.TXT"
12020	PRINT "Make the following selections for ";D$;" file:":

	PRINT:

	PRINT "Current drive selected: ";LEFT$(FILE$,1):

	PRINT "Enter new drive (A - P) or <RETURN> to keep current selection: ";
12030	INLEN=1:

	GOSUB 60030:

	IF (IN$<"A" OR IN$>"P") AND IN$<>""

		THEN	PRINT:

			PRINT BELL$:

			PRINT "Invalid drive selection!":

			PRINT "Limit choice between 'A' and 'P'! ";:

			GOTO 12030
12040	PRINT:

	PRINT:

	IF IN$=""

		THEN	FILE1$=LEFT$(FILE$,2):

		ELSE	FILE1$=IN$+":"
12050	X=INSTR(FILE$,"."):

	IF X=0

		THEN 	FILE$=FILE$+".":

			GOTO 12050
12060	PRINT "Current filename selected (w/out extension): ";:

	PRINT MID$(FILE$,3,X-3):

	PRINT "Enter new filename or <RETURN> to keep current selection: ";
12070	INLEN=8:

	GOSUB 60030:

	PRINT:

	PRINT:	

	IF IN$=""

		THEN	FILE1$=FILE1$+MID$(FILE$,3,X-3):

		ELSE	FILE1$=FILE1$+IN$
12080	PRINT "Do you wish to have an extension on your ";D$;" filename? ";:

	INLEN=1:

	GOSUB 60030:

	IF IN$="N"

		THEN	12110:

		ELSE	IF IN$<>"Y"

				THEN	12080
12090	PRINT:

	PRINT:

	PRINT "Current extension selected: ";MID$(FILE$,X+1,LEN(FILE$)):

	PRINT "Enter new extension or <RETURN> to keep current selection: ";
12100	INLEN=3:

	GOSUB 60030:

	IF IN$=""

		THEN	FILE1$=FILE1$+MID$(FILE$,X,LEN(FILE$)):

		ELSE	FILE1$=FILE1$+"."+IN$
12110	PRINT:

	PRINT:

	PRINT "You have entered: ";FILE1$
12120	PRINT:

	PRINT "Is this correct? (Y/N/Q) ";:

	INLEN=1:

	GOSUB 60030:

	IF IN$="Y"

		THEN 	12130:

		ELSE	IF IN$="N"

				THEN	PRINT:

					PRINT:

					GOTO 12000:

				ELSE	IF IN$<>"Q"

						THEN	12120:

						ELSE	12140
12130	IF D

		THEN	OUTFILE$=FILE1$:

		ELSE	INFILE$=FILE1$
12140	RETURN


60000	ON ERROR GOTO 10000:

	DIM PNUM$(100),PLEN$(100),PTOPIC$(100):

	HOME$=CHR$(30):

	CLS$=CHR$(26)+"TEXT TO HELP"+SPACE$(44)+"LEEMAC  JUN 87":

	CLS$=CLS$+CHR$(10)+CHR$(13)+"FILE CONVERTER v1.2"+CHR$(10)+CHR$(13):

	BELL$=CHR$(7)
60001	CDOWN$=STRING$(24,10):

	COVER$=SPACE$(80):

	CAPS=1:

	RETURN


60010	CLOSE 3:

	OPEN "R",3,"TXT2HLP.HLP",78:

	FIELD #3, 78 AS TX$:

	FIELD #3, 5 AS SN$, 5 AS SL$, 48 AS ST$
60011	X=1:

	WHILE+ X>0:

		GET#3,X:

		IF TX$=STRING$(78,0)

			THEN	X=X+1:

			ELSE	X=-1
60012		IF X=10

			THEN	PRINT BELL$:

				PRINT "Help file not available!":

				PRINT CHR$(34);"TXT2HLP.HLP";CHR$(34);:

				PRINT " required to run this program.":

				PRINT BELL$:

				END
60013	WEND:

	RETURN


60030	IN$="":

	PRINT BELL$;:

	FOR J=1 TO INLEN
60031		A$=INKEY$:

		IF A$=""

			THEN	60031
60032		IF A$=CHR$(8)

			THEN	J=J-1:

				IF LEN(IN$)>1

					THEN	IN$=LEFT$(IN$,LEN(IN$)-1):

						PRINT A$;" ";A$;:

						GOTO 60031:

					ELSE	IN$="":

						PRINT A$;" ";A$;:

						GOTO 60031
60033		IF A$=CHR$(13)

			THEN	J=INLEN:

				GOTO 60035
60034		IN$=IN$+A$:

		PRINT A$;
60035	NEXT J:

	IF CAPS

		THEN	GOSUB 60040
60036	CAPS=1:

	RETURN


60040	FOR J=1 TO LEN(IN$):

		IF MID$(IN$,J,1)>CHR$(64)

			THEN	MID$(IN$,J,1)=CHR$(ASC(MID$(IN$,J,1)) AND 95)
60041	NEXT J:

	RETURN


61000 '	Things to add:


61001 '	1) Ability to see remaining space on disk.
61002 '	2) Ability to have imbedded prompt lines in ovl/help file, which

	   would give the prompt, and the screen positioning for the

	   prompt for user input.
61003 '	3) A full compliment of error codes and error trapping.