10 ' MENU.BAS  NAVPROGseven Air Navigation Menu   1-Jan-82    Rev 01/05/85
20 '
30 ' (c) Copyright 1982 Alan Bose
40 ' President, Taildragger Flyers
50 ' Ross Field, Benton Harbor, MI
60 '
70 ' CP/M modifications (c) 1982 by Glen Hassebrock, Jr.
80 '
90 CLEAR:WIDTH 120:ON ERROR GOTO 640:DEFINT I-N
100 DEF FNC$(C1,C2)=Y$+CHR$(C1+31)+CHR$(C2+31)
110 BL$=CHR$(7):E$=CHR$(27):ER$=E$+"E":L$=E$+"l":P$=E$+"p":Q$=E$+"q"
120 J1$=E$+"J":Y$=E$+"Y":PRINT ER$
130 '
140 OPEN"I",1,"DISKAID.DAT":LINE INPUT #1,ID$
150 CLOSE:IF ID$="172" THEN 200
160 PRINT ER$"At tone, place NAVPROGseven PROGRAM DISK on drive A:":PRINT
170 PRINT BL$"Press any key after mounting disk.";:X$=INPUT$(1)
180 RESET:GOTO 140
190 '
200 OPEN"I",1,"B:DISKBID.DAT":LINE INPUT#1,ID$
210 CLOSE:IF ID$="182" THEN 260
220 PRINT ER$"Place NAVPROGseven DATA DISK on drive B:"
230 PRINT BL$"Press any key after mounting disk.";:X$=INPUT$(1)
240 PRINT:RESET:GOTO 200
250 '
260 PRINT E$"x1"FNC$(25,1)ER$FNC$(1,1)ER$
270 HD$="N A V P R O G s e v e n   A I R   N A V I G A T I O N   M E N U"
280 PRINT P$;TAB(40-LEN(HD$)/2)HD$TAB(81)
290 PRINT Q$;TAB(26)"Copyright 1982 Alan Bose"
300 PRINT FNC$(7,20)"1  -  Input/revise Airport & Navaid Data"
310 PRINT FNC$(9,20)"2  -  Input/revise Aircraft Performance Data"
320 PRINT FNC$(11,20)"3  -  Automatic Route Preparation"
330 PRINT FNC$(13,20)"4  -  Air Navigation & Flight Planning"
340 PRINT FNC$(15,20)"5  -  Navigate Pre-planned Route"
350 PRINT FNC$(17,20)"6  -  Sort & list data on file"
360 PRINT FNC$(22,26)J1$"Enter selection  <EXIT>  ";
370 X$=INPUT$(1):PRINT X$:X=VAL(X$)
380 IF X$<>CHR$(13) THEN 530
390 PRINT ER$;TAB(20);"USER SUPPORTED SOFTWARE":PRINT
400 PRINT "User-Supported Software is based on the belief that program development"
410 PRINT "should be supported by the computer community, that the value of"
420 PRINT "software is best assessed by the user, not the developer, and that"
430 PRINT "copying software should be encouraged, not restricted.":PRINT
440 PRINT "But its success depends on the trustworthy actions of both authors"
450 PRINT "and end-users.":PRINT
460 PRINT "If you find these programs a useful and valuable addition to your"
470 PRINT "software library, the suggested contribution is $45 (US) to Alan Bose,"
480 PRINT "1224 Allison Lane, Schaumburg, IL 60194.  See file README.DOC for more"
490 PRINT "information on documentation, source code, etc."
500 PRINT: X$=INPUT$(1)
510 PRINT ER$"...services terminated. Squawk 1200."
520 PRINT"Frequency change approved. Have a good flight.":PRINT:SYSTEM
530 IF X<1 OR X>6 THEN PRINT BL$:GOTO 360
540 '
550 PRINT ER$"Standby one..."
560 ON X GOTO 570,580,590,600,620,630
570 RUN"AIRINPUT"
580 RUN"AIRCRAFT"
590 RUN"AUTONAV"
600 OPEN"I",1,"B:FLIGHT.SEQ":CLOSE:RUN"NAVPROG7"
610 RUN"AIRROUTE"
620 RUN"OLDROUTE"
630 RUN"AIRALPHA"
640 'error trap
650 IF ERR=53 AND ERL=600 THEN RESUME 610
660 IF ERL=200 AND (ERR=53 OR ERR=64) THEN RESUME 220
670 IF ERL=140 AND ERR=53 THEN RESUME 160
680 ON ERROR GOTO 0