10 ' AIRCRAFT.BAS   NAVPROGseven Aircraft Data Entry    22-Jan-82   Rev 6/11/82
20 '
30 ' (c) Copyright 1982 Alan Bose
40 ' President, Taildragger Flyers
50 ' Ross Field, Benton Harbor, MI
60 '
70 ' CP/M  modifications (c) 1982 by Glen Hassebrock, Jr.
80 '
90 CLEAR:ON ERROR GOTO 670:WIDTH 255:DEFINT I-J
100 BL$=CHR$(7):E$=CHR$(27):ER$=E$+"E":PG$=E$+"p":QG$=E$+"q":Y$=E$+"Y"
110 L$=E$+"l":J$=E$+"j":K$=E$+"k":J1$=E$+"J"
120 DEF FNC$(C1,C2)=Y$+CHR$(C1+31)+CHR$(C2+31)
130 HD$="A I R C R A F T   P E R F O R M A N C E"
140 PRINT FNC$(25,1)ER$E$"H"ER$PG$TAB(40-(LEN(HD$)/2))HD$TAB(79)QG$
150 PRINT FNC$(5,1)"Aircraft identification?  <MENU>  N"J$STRING$(7,95);K$;
160 LINE INPUT AI$:PRINT J1$:IF AI$="" THEN 630
170 F$="N"+AI$
180 OPEN "I",2,"B:"+F$:PRINT"Found aircraft performance data for "F$" ";
190 LINE INPUT #2,AT$:PRINT AT$:INPUT#2,RU:INPUT#2,T9:INPUT#2,G9:INPUT#2,D9
200 INPUT #2,NA:INPUT#2,NS:INPUT#2,NF:INPUT#2,NB:INPUT#2,PH:CLOSE:GOTO 220
210 PRINT FNC$(7,1)J1$"No data on file for "F$
220 PRINT FNC$(11,1)"Enter `E' to EXIT"FNC$(12,1)"Enter `D' to DELETE"
230 PRINT FNC$(10,1)"Enter aircraft type  "J$STRING$(30,95)K$;
240 LINE INPUT X$:IF X$="E" OR X$="e" THEN 140
250 IF X$="D" OR X$="d" THEN KILL"B:"+F$:GOTO 140
260 IF LEN(X$)=1 THEN PRINT BL$:GOTO 220
270 PRINT K$AT$:PRINT J1$;:IF X$<>"" THEN AT$=X$
280 PRINT "Fuel used for start-up, taxi & run-up?  ";
290 IF RU>0 THEN PRINT"<"RU">  ";
300 PRINT J$STRING$(4,95)" gallons"K$;:LINE INPUT RU$
310 IF RU$<>"" THEN RU=VAL(RU$)
320 PRINT"Enter normal cruising altitude  ";:IF NA>0 THEN PRINT"<"NA">  ";
330 PRINT J$STRING$(5,95)" ft"K$;:LINE INPUT X$:IF X$<>"" THEN NA=VAL(X$)
340 IF NA=0 THEN PRINT BL$:GOTO 320
350 PRINT"Enter time required to climb to"NA"feet  ";
360 IF T9>0 THEN PRINT"<"T9">  ";
370 PRINT J$STRING$(3,95)" minutes"K$;:LINE INPUT X$:IF X$<>"" THEN T9=VAL(X$)
380 IF T9=0 THEN PRINT BL$:GOTO 350
390 PRINT"Enter fuel required to climb to"NA"feet  ";
400 IF G9>0 THEN PRINT"<"G9">  ";
410 PRINT J$STRING$(3,95)" gallons"K$;:LINE INPUT X$:IF X$<>"" THEN G9=VAL(X$)
420 IF G9=0 THEN PRINT BL$:GOTO 390
430 PRINT"Enter distance required to climb to"NA"feet  ";
440 IF D9>0 THEN PRINT"<"D9">  ";
450 PRINT J$STRING$(3,95)" nm"K$;:LINE INPUT X$:IF X$<>"" THEN D9=VAL(X$)
460 IF D9=0 THEN PRINT BL$:GOTO 430
470 PRINT"Enter normal cruise true airspeed at"NA"feet  ";
480 IF NS>0 THEN PRINT"<"NS">  ";
490 PRINT J$STRING$(3,95)" kts"K$;:LINE INPUT X$:IF X$<>"" THEN NS=VAL(X$)
500 IF NS<40 THEN PRINT BL$:GOTO 470
510 PRINT"Enter normal fuel consumption at"NA"feet  ";
520 IF NF>0 THEN PRINT"<"NF">  ";
530 PRINT J$STRING$(4,95)" gal/hr"K$;:LINE INPUT X$:IF X$<>"" THEN NF=VAL(X$)
540 IF NF<6 THEN PRINT BL$:GOTO 510
550 PRINT"Enter normal fuel on board  ";:IF NB>0 THEN PRINT"<"NB">  ";
560 PRINT J$STRING$(4,95)" gal"K$;:LINE INPUT X$:IF X$<>"" THEN NB=VAL(X$)
570 IF NB<10 THEN PRINT BL$:GOTO 550
580 PRINT"Enter cost per hour  ";:IF PH>0 THEN PRINT"<"PH">  ";
590 PRINT"$"J$STRING$(4,95)K$;:LINE INPUT X$:IF X$<>"" THEN PH=VAL(X$)
600 IF PH<15 THEN PRINT BL$:GOTO 580
610 OPEN "O",2,"B:"+F$:PRINT#2,AT$:PRINT#2,RU:PRINT#2,T9:PRINT#2,G9
620 PRINT #2,D9:PRINT#2,NA:PRINT#2,NS:PRINT#2,NF:PRINT#2,NB:PRINT#2,PH
630 CLOSE
640 OPEN"I",1,"B:FLIGHT.SEQ":CLOSE
650 PRINT ER$"Standby one...":RUN"NAVPROG7"
660 RUN"MENU"
670 'error trap
680 IF ERR=53 AND ERL=180 THEN RESUME 210
690 IF ERR=53 AND ERL=640 THEN RESUME 660
700 IF ERR=53 AND ERL=250 THEN RESUME 140
710 ON ERROR GOTO 0