10 REM PROGRAM "RISE-SET.BAS," A MBASIC PROGRAM CALCULATING THE LOCAL HOUR ANGLE
20 REM    AND THE LOCAL AZMUTH OF THE RISING OF AN ASTRONOMICAL BODY
30 REM       GIVEN ITS DECLINATION AND THE OBSERVERS LATITUDE
40 REM           REVISED 4-19-1985, MIKE FINERTY, TUCSON
50 REM ***********************************************************************
60 PI = 3.1415926#
70 CONST = 1.00273790926#
80 INPUT "DECLINATION OF BODY IN DEC. DEGREES";D
90 INPUT "LATITUDE OF OBSERVER IN DEGREES.MINS "; LAT
100 DEC = D*PI/180
110 LATITUDE = 100/60*(LAT - INT(LAT))+INT(LAT)
120 L = LATITUDE*PI/180
130 TEST = ABS(DEC)
140 IF TEST > PI/2-ABS(L) THEN 470
150 LHACOS = - TAN(L)*TAN(DEC)
160 AZCOS = SIN(DEC)/COS(L)
170 LHA =PI/2-ATN(LHACOS/(1-LHACOS^2)^.5)
180 AZ = PI/2-ATN(AZCOS/(1-AZC0S^2)^.5)
190 AZ = AZ/PI*180
200 LHA=LHA/PI*12
210 LHA = 24-LHA
220 PRINT "RISING AZMUTH =";AZ;"DEGREES, SETTING AZMUTH =";360-AZ;"DEGREES"
230 PRINT "LHA RISING =";LHA;"HOURS, LHA SETTING =";24-LHA;"HOURS"
240 PRINT "OBJECT VISIBLE FOR";2*(24-LHA);"HOURS."
250 PRINT "ALTITUDE AT UPPER CULMINATION (TRANSIT) =";90-ABS(L-DEC)*180/PI;"DEGREES"
260 IF DEC = L THEN PRINT "CULMINATION AT ZENITH"
270 IF DEC>L THEN PRINT "TRANSIT NORTH OF ZENITH"
280 IF DEC<L THEN PRINT "TRANSIT SOUTH OF ZENITH"
290 INPUT "RIGHT ASCENTION =";RA
300 INPUT "LONGITUDE = ";LONG
310 LONG = (LONG + (100/60*(LONG - INT(LONG))))/15
320 INPUT "SIDERAIAL TIME IN DECIMAL HOURS, 00:0000 UT, YOUR DAY", STIME
330 LMTTRANS = (STIME - RA +LONG - INT(LONG))*CONST
340 IF LMTTRANS < 0 THEN LMTTRANS = LMTTRANS + 24
350 PRINT "OBJECT TRANSITS AT: ";INT(LMTTRANS);"HRS";60*(LMTTRANS-INT(LMTTRANS));"MINS LOCAL TIME"
360 IF FLAG = 1 THEN 430
370 FLAG = 0
380 RISETIME = LMTTRANS - CONST*(24-LHA)
390 IF RISETIME < 0 THEN RISETIME = RISETIME + 24
400 PRINT "OBJECT WILL RISE AT: ";RISETIME; " HOURS, LOCAL TIME"
410 SETTIME = LMTTRANS +CONST*(24-LHA)
420 PRINT "OBJECT WILL SET AT: ";SETTIME;" HOURS, LOCAL TIME"
430 PRINT "DO YOU WANT ANOTHER OBJECT ? Y/N?"
440 INPUT ANS$
450 IF ANS$ = "Y" GOTO 10
460 END
470 IF SGN(DEC) = SGN(L) THEN PRINT "OBJECT DOES NOT SET"
480 IF SGN(DEC) = -1*SGN(L) THEN PRINT "OBJECT DOES NOT RISE ABOVE HORIZON"
490 FLAG = 1
500 GOTO 250