10 REM THIS IS PROGRAM "TIME" LOCAL SIDERIAL TIME IS CALCULATED
20 REM GIVEN THE DATE, HOUR, MINIT AND SECOND AND THE OBSERVER'S LONGITUDE
30 REM PROGRAM IS BY MIKE FINERTY MAKING USE OF PROGRAMS IN SKY AND TELESCOPE'S
40 REM COMPUTER SECTION.
50 DEFDBL A-Z
60 PRINT "PLEASE INPUT DATA: "
70 INPUT "LONGITUDE = ";L2
80 LPRINT "LONGITUDE = ";L2;" DEGREES"
90 L2 = L2/15
100 REM L2 IS NOW LONGITUDE IN DECIMAL HOURS
110 INPUT "YEAR =";Y
120 LPRINT "YEAR = ";Y
130 INPUT "MONTH = ";M
140 LPRINT "MONTH = ";M
150 INPUT "DAY = ";D2
160 LPRINT "DAY =";D2
170 REM THIS IS UNIVERSAL TIME
180 INPUT "HOURS =";A1
190 LPRINT "HOURS =";A1
200 INPUT "MINUTES =";A2
210 LPRINT "MINUTES =";A2
220 INPUT "SECONDS =";A3
230 LPRINT "SECONDS =";A3
240 F1 = (A3+60*A2+3600*A1)/86400!-.5
250 J = - INT(7*(INT((M+9)/12)+Y)/4)
260 S = SGN(M-9)
270 A4 = ABS(M-9)
280 J1 = INT(Y+S*INT(A4/7))
290 J1 = - INT((INT(J1/100)+1)*3/4)
300 J = J + INT(275*M/9)+D2+J1
310 J = J+1.72103E+06+367*Y
320 J = J - 2
330 PRINT "JULIAN DAY: ";J;" FRACTION OF A DAY:";F1
340 LPRINT "JULIAN DAY: ";J;" FRACTION OF A DAY:";F1
350 REM CALCULATE GREENWICH SIDERIAL TIME FIRST
360 D = J -2.45155E+06
370 D = D - 5
380 T = D/36525!
390 T1 = INT(T)
400 J0 = T1*36525!+2.45155E+06
410 J0 = J0 -5
420 T2 =(J - J0 +.5)/36525!
430 S0 = 24110.54841#+184.812866#*T1
440 S0 = S0 + 8640184.812860002#*T2
450 S0 = S0 + (.093104*T*T)
460 S0 = S0 -(.0000062*T*T*T)
470 S0 = S0/86400!
480 S1 = INT(S0)
490 S0 = S0 - S1
500 S0 = 24*(S0+(F1+.5)*1.002737909#)
510 IF S0<0 THEN S0 = S0+24
520 IF S0>24 THEN S0 = S0 - 24
530 LST = S0 - L2
540 LSTDEG = LST*15
550 IF LST < 0 THEN LST = LST + 24
560 PRINT "LOCAL SIDERIAL ANGLE (ARIES) IN DECIMAL DEGREES: ";LSTDEG
570 H = INT(LST)
580 M1 = 60 * (LST - H)
590 M = INT(M1)
600 S = 60 * (M1 - M)
610 PRINT "LOCAL SIDERIAL TIME:";H;"HRS";M;"MINS";S;"SECS"
620 LPRINT "LOCAL SIDERIAL TIME:";H;"HRS";M;"MINS";S;"SECS"
630 PRINT "DO YOU WANT A DIFFERENT TIME? Y/N?"
640 INPUT ANS$
650 IF ANS$ = "Y" THEN 100
660 END