10 REM THIS IS PROGRAM "POSITION" BY M. FINERTY
20 REM THIS PROGRAM CALCULATES DECLINATION AND RIGHT ASCENTION
30 REM FROM ALTITUDE, AZMUTH, LATITUDE AND SIDERIAL TIME
40 REM**************************************************
50 C1 = 180/3.1415926#
60 C2 = 1/C1
70 REM
80 PRINT "PLEASE INPUT DATA"
90 INPUT "LATITUDE =", LAT
100 LAT = LAT*C2
110 INPUT "ALTITUDE = ", ALT
120 ALT = ALT*C2
130 INPUT "AZMUTH =", AZ
140 AZ = AZ*C2
150 DECSIN = SIN(LAT)*SIN(ALT) + COS(LAT)*COS(ALT)*COS(AZ)
160 DECLINAT = ATN(DECSIN/((1-DECSIN^2)^.5))
170 DEC = DECLINAT*C1
180 PRINT "DECLINATION = "; DEC;
190 IF DEC < 0 THEN PRINT "  S"
200 IF DEC >=0 THEN PRINT "  N"
210 TSIN = SIN(AZ)*COS(ALT)/COS(DECLINAT)
220 TCOS = (SIN(ALT) - SIN(LAT)*SIN(DECLINAT))/(COS(LAT)*COS(DECLINAT))
230 HA = ATN(TSIN /((1-TSIN^2)^.5))
240 HA = HA*C1
260 HA = ABS(HA)
270 IF TSIN < 0 AND TCOS >=0 THEN PRINT "HOUR ANGLE ="; HA;" DEGREES"
280 IF TSIN < 0 AND TCOS >= 0 THEN TIMEANG = HA
290 IF TSIN < 0 AND TCOS < 0 THEN PRINT "HOUR ANGLE ="; 180 - HA;" DEGREES"
300 IF TSIN < 0 AND TCOS < 0 THEN TIMEANG = 180 - HA
310 IF TSIN >= 0 AND TCOS < 0 THEN PRINT "HOUR ANGLE ="; 180 + HA;" DEGREES"
320 IF TSIN >= 0 AND TCOS >=0 THEN PRINT "HOUR ANGLE ="; 360 - HA;" DEGREES"
330 IF TSIN >= 0 AND TCOS < 0 THEN TIMEANG = 180 + HA
340 IF TSIN >= 0 AND TCOS >= 0 THEN TIMEANG = 360 - HA
350 INPUT "LOCAL SIDERIAL TIME HRS,MINS = "; HRS,MINS
360 SIDTIME = 15*HRS + MINS/4
370 RA = SIDTIME + 360 - TIMEANG
380 IF RA > 360 THEN RA = RA -360
390 PRINT "RIGHT ASCENTION ="; RA;"DEGREES"
400 RTASC = INT(RA/15)
410 PLUSMINS = 60*(RA/15 - RTASC)
420 PRINT "RIGHT ASCENTION = ";RTASC;"HRS  "; PLUSMINS;"MINS"
430 PRINT "DO YOU WANT ANOTHER OBJECT Y/N?"
440 INPUT ANS$
450 IF ANS$ = "Y" THEN 110
460 END