10 REM THIS IS A NEVADA BASIC 12 DIGIT PROGRAM WRITTEM BY MIKE FINERTY
   20 REM IT WILL OPPERATE OUTSIDE OF THE NORMAL RANGE OF THE LANGUAGE AS
   30 REM SET UP BY ELLIS COMPUTING (TM), USING LOG FACORING TECHNIQUES
   40 LPRINT "PROGRAM POISSON:  SINGLE TERMS OF THE POISSON DISTRIBUTION"
   50 PRINT "PROGRAM POISSON:  SINGLE TERMS OF THE POISSON DISTRIBUTION"
   60 LPRINT 
   70 PRINT 
   80 REM X IS NUMBER OF OCCURENCES
   90 INPUT "X = ",X
  100 LPRINT "X = ";X
  110 PRINT "RUNTIME = ";0.12*X;" SECONDS"
  120 PRINT 
  130 REM LAMBDA IS AVERAGE EXPECTATION
  140 INPUT "LAMBDA = ",L
  150 LPRINT "LAMBDA = ";L
  160 PRINT "CALCULATIONS IN PROGRESS"
  170 FOR N=1 TO X
  180 LET Y=Y-LOG10(N)
  190 NEXT N
  200 LET Z=X*LOG10(L)
  210 LET R=-L/LOG(10)
  220 REM P IS THE LOGARITHM OF THE POISSON PROBABILITY
  230 LET P=Y+Z+R
  240 LPRINT 
  250 LPRINT "LOGPROB = ";P
  260 LPRINT "POISSON PROBABILITY = ";10^(P-INT(P)+1);"TEN";INT(P)-1
  270 LET G2=10-INT(LOG10(ABS(P)))-INT(LOG10(1.25*X))
  280 LPRINT "CALCULATIONS GOOD TO ";G2;" DIGITS"
  290 PRINT "LOGPROB = ";P
  300 PRINT "POISSON PROBABILITY = ";10^(P-INT(P)+1);"TEN";INT(P)-1
  310 PRINT "CALCULATIONS GOOD TO ";G2;" DIGITS"
  320 PRINT "--ooOOOoo--"
  330 LPRINT "--oo000oo--"
  340 END